InputBox Function not as flexible as needed

I'm using a simple inputbox function to query a number of variables from the workbook user, to be used in a new object created from a class module.

I'd like to name the new object a unique concatenation of the variables being stored within it to archive in a library for tracking.

Currently, my functions (seven in all) are written as such:

Function candfirstname() As String

Dim Prompt As String
Dim Title As String
'Declares Prompt and Title as string variables

Prompt = "Please enter the candidate's first name"
Title = "Candidate First Name"
'Assigns string values to Prompt and Title for display in the InputBox

candfirstname = InputBox(Prompt, Title)
'Calls InputBox Application

End Function

I run into trouble because everytime I need to reference the returned variable in my primary macro I call a new InputBox (the function). I will also need to error check these user inputs in the function to ensure they're the appropriate datatype, thus it makes sense to return a different variable name from the function.

How can I write my functions to call the inputbox function (function within a function) in such a way that a different variable name is returned? Please bear in mind the function should allow for IF statements to qualify the user input before being returned to the sub.

I've included the workbook for reference. The primary macro is named "AddNMP", and the sub "InputBoxNewMarginPlacement" will ultimately be inserted / called into / by "AddNMP." The code is a bit messier than usual because I've been trying to test the concatenation, but those lines have been remarked - feel free to ignore.

What exactly are you trying to concatenate?

How are the input boxes being duplicated?

What is it you want to change about them?

I've tried to put it into context below.

Function candfirstname
Function calls InputBox function to query user for candidate's first name and stores in string candfirstname

' candfirstname Function
' Function calls an InputBox function to record candfirstname as a string value

Function candfirstname() As String

Dim Prompt As String
Dim Title As String
'Declares Prompt and Title as string variables

Prompt = "Please enter the candidate's first name"
Title = "Candidate First Name"
'Assigns string values to Prompt and Title for display in the InputBox

candfirstname = InputBox(Prompt, Title)
'Calls InputBox Application

End Function

Sub InputBoxNewMarginPlacement
Calls Class CTempCandidate to create object for storage of user input in an array of strings, singles and integers. The Functions are called for user input, then passed to a class to create a new object. Hit Ctrl+F and search for [ISSUE] to see the two specific areas that call the function and explain the duplicate InputBoxes. The solution I had in mind involved adding a RETURN to the Function and differentiating the Function name and the returned variable. Thoughts on how to change the Function to achieve this?

' InputBoxNewMarginPlacement Macro
' Macro calls multiple inputboxes to assign values for loading into NewCandProfile object,_
' created from CTempCandidate Class


Sub InputBoxNewMarginPlacement()

'Calls Class CTempCandidate to create New Object comprised of candidate variables in_
'String, Double and Integer Types

Dim NewCandProfile As New CTempCandidate
'Declares new Object named NewCandProfile from Class CTempCandidate

'Dim ConcatenationProof As String
[ISSUE]'Dim objectfirstname As String
'objectfirstname = candfirstname[ISSUE]
'Dim objectlastname As String
'objectlastname = candlastname
'Dim objectclientname As String
'objectclientname = clientname
'Delares a new variable as a string for naming of NewCandProfile object
'to test concatenation in MsgBox at end of Sub

Dim sFirstName As String
Dim sLastName As String
Dim sClientName As String
Dim sPayRate As Double
Dim sBillRate As Double
Dim sEmployStatus As Double
Dim sSplitPercent As Integer
'Declares variables in primary macro to receive variables passed from InputBox_
'these variables are then passed to object NewCandProfile

[ISSUE]sFirstName = candfirstname[ISSUE]
sLastName = candlastname
sClientName = clientname
sPayRate = candpayrate
sBillRate = candbillrate
sEmployStatus = employmentstatus
sSplitPercent = splitpercentage
'InputBox series runs and passes variables into primary macro

'ConcatenationProof = objectfirstname & objectlastname & objectclientname

Set NewCandProfile = New CTempCandidate
 NewCandProfile.sFirstName = sFirstName
 NewCandProfile.sLastName = sLastName
 NewCandProfile.sClientName = sClientName
 NewCandProfile.sCandPayRate = sPayRate
 NewCandProfile.sCandBillRate = sBillRate
 NewCandProfile.sEmployStatus = sEmployStatus
 NewCandProfile.sSplitPercent = sSplitPercent
'Creates an object named NewCandProfile from the class CTempCandidate then sets values in new object_
'as those returned from InputBox series

'MsgBox ConcatenationProof
'MsgBox "Candidate First Name: " & NewCandProfile.sFirstName & vbCrLf & "Candidate Last Name: " & NewCandProfile.sLastName & vbCrLf & "Client Name: " & NewCandProfile.sClientName & vbCrLf & "Candidate Pay Rate: " & NewCandProfile.sCandPayRate & vbCrLf & "Candidate Bill Rate: " & NewCandProfile.sCandBillRate & vbCrLf & "Employment Status: " & NewCandProfile.sEmployStatus & vbCrLf & "Referral Split: " & NewCandProfile.sSplitPercent
'Calls a MsgBox to display results from class

End Sub

Class CTempPlacement (for reference)

'Class designed to create a NewCandidateProfile

Private cCandFirstName As String
Private cCandLastName As String
Private cClientName As String
Private cCandPayRate As Double
Private cCandBillRate As Double
Private cEmployStatus As Double
Private cSplitPercent As Integer
'#######################################################################
'Creates an exchange path for input and output of Candidate's First Name
Public Property Get sFirstName() As String
    sFirstName = cCandFirstName
End Property
Public Property Let sFirstName(Value As String)
    cCandFirstName = Value
End Property
'###########################################################################
'Creates an exchange path for input and output of the Candidate's Last Name
Public Property Get sLastName() As String
    sLastName = cCandLastName
End Property
Public Property Let sLastName(Value As String)
    cCandLastName = Value
End Property
'#########################################################################
'Creates an exchange path for input and output of Client Organization Name
Public Property Get sClientName() As String
    sClientName = cClientName
End Property
    Public Property Let sClientName(Value As String)
        cClientName = Value
    End Property
'#####################################################################
'Creates an exchange path for input and output of Candidate's Pay Rate
Public Property Get sCandPayRate() As Double
    sCandPayRate = cCandPayRate
End Property
Public Property Let sCandPayRate(Value As Double)
    cCandPayRate = Value
End Property
'######################################################################
'Creates an exchange path for input and output of Candidate's Bill Rate
Public Property Get sCandBillRate() As Double
    sCandBillRate = cCandBillRate
End Property
Public Property Let sCandBillRate(Value As Double)
    cCandBillRate = Value
End Property
'############################################################################
'Creates an exchange path for input and output of Candidate Employment Status
Public Property Get sEmployStatus() As Double
    sEmployStatus = cEmployStatus
End Property
Public Property Let sEmployStatus(Value As Double)
    cEmployStatus = Value
End Property
'##########################################################################
'Creates an exchange path for input and output of Referral Split Percentage
Public Property Get sSplitPercent() As Integer
    sSplitPercent = cSplitPercent
End Property
Public Property Let sSplitPercent(Value As Integer)
    cSplitPercent = Value
End Property

Do you actually need the variables?

Can't you assign directly to the object from the functions?

What wll you be concatentating the name of the object to?

To me it sounds like you want to do that for some sort of dynamic variable name.

By the way, this is what I was meaning about not needing the variables.

Sub InputBoxNewMarginPlacement()
'InputBox series runs and passes variables into primary macro

'ConcatenationProof = objectfirstname & objectlastname & objectclientname

    Set NewCandProfile = New CTempCandidate
    NewCandProfile.sFirstName = candfirstname
    NewCandProfile.sLastName = candlastname
    NewCandProfile.sClientName = clientname
    NewCandProfile.sCandPayRate = candpayrate
    NewCandProfile.sCandBillRate = candbillrate
    NewCandProfile.sEmployStatus = employmentstatus
    NewCandProfile.sSplitPercent = splitpercentage
    'Creates an object named NewCandProfile from the class CTempCandidate then sets values in new object_
    'as those returned from InputBox series

    'MsgBox ConcatenationProof
    'MsgBox "Candidate First Name: " & NewCandProfile.sFirstName & vbCrLf & "Candidate Last Name: " & NewCandProfile.sLastName & vbCrLf & "Client Name: " & NewCandProfile.sClientName & vbCrLf & "Candidate Pay Rate: " & NewCandProfile.sCandPayRate & vbCrLf & "Candidate Bill Rate: " & NewCandProfile.sCandBillRate & vbCrLf & "Employment Status: " & NewCandProfile.sEmployStatus & vbCrLf & "Referral Split: " & NewCandProfile.sSplitPercent
    'Calls a MsgBox to display results from class

End Sub

This part of the code is taking the return values of the functions and assigning them to the new candidate.

NewCandProfile.sFirstName = candfirstname
    NewCandProfile.sLastName = candlastname
    NewCandProfile.sClientName = clientname
    NewCandProfile.sCandPayRate = candpayrate
    NewCandProfile.sCandBillRate = candbillrate
    NewCandProfile.sEmployStatus = employmentstatus
    NewCandProfile.sSplitPercent = splitpercentage

I would recommend a more direct approach, there's no need to call a separate function for each variable, and it appears things are getting confusing by trying. Just collect the information directly in the main macro:

'Note, Type:=1 is numeric, Type:=2 is string
Do
    sfirstname = Application.InputBox("Enter First Name", "First Name", Type:=2)
    If Len(sfirstname) > 0 Then Exit Do
Loop
Do
    sLastname = Application.InputBox("Enter Last Name", "Last Name", Type:=2)
    If Len(sLastname) > 0 Then Exit Do
Loop
Do
    sClientName = Application.InputBox("Enter Client Name", "Client Name", Type:=2)
    If Len(sClientName) > 0 Then Exit Do
Loop
Do
    sPayRate = Application.InputBox("Enter Candidate Pay Rate", "Pay Rate", Type:=1)
    If Len(sPayRate) > 0 Then Exit Do
Loop
Do
    sBillRate = Application.InputBox("Enter Candidate Billing Rate", "Bill Rate", Type:=1)
    If Len(sBillRate) > 0 Then Exit Do
Loop
Do
    sEmployStatus = Application.InputBox("Enter Employment Status", "Status", Type:=2)
    If Len(sEmployStatus) > 0 Then Exit Do
Loop
Do
    sSplitPercent = Application.InputBox("Enter Split Percentage", "Status", Type:=1)
    If Len(sSplitPercent) > 0 Then Exit Do
Loop


Set NewCandProfile = New CTempCandidate
 NewCandProfile.sfirstname = sfirstname
 NewCandProfile.sLastname = sLastname
 NewCandProfile.sClientName = sClientName
 NewCandProfile.sCandPayRate = sPayRate
 NewCandProfile.sCandBillRate = sBillRate
 NewCandProfile.sEmployStatus = sEmployStatus
 NewCandProfile.sSplitPercent = sSplitPercent

I would also recommend you don't use

Dim NewCandProfile As New CTempCandidate

just use

Dim NewCandProfile As CTempCandidate

and then set to a New instance as you are doing. that may also help show you why you are getting a 438 error-you're trying to assign a string to an object

your class properties should validate the input data but using application.inputbox as Jerry demonstrated gives you the option to specify a type unlike the vba.inputbox function