How to modify Worksheet_Change Macro VBA code from Range to Cell

The below VBA code works well for Row1 data. Unfortunately, I have more than one row of data that will need the same change function. How could I modify the code to work for Row2, Row3 thru Row99? Note each row would have different conversion factors (Ex. for Row2 instead of 86.67, 28 it would be 184.17, 14)

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rAction As Range
Set rAction = Range("B1:D1")
If Intersect(rAction, Target) Is Nothing Then Exit Sub
If Target.Count > 1 Then Exit Sub
Application.EnableEvents = False
ady = Target.Address(rowabsolute:=False, columnabsolute:=False)
If ady = "B1" Then
[C1] = [B1] / 86.67
[D1] = [C1] / 28
End If
If ady = "C1" Then
[B1] = [C1] * 86.67
[D1] = [C1] / 28
End If
If ady = "D1" Then
[C1] = [D1] * 28
[B1] = [C1] * 86.67
End If
Application.EnableEvents = True
End Sub

If you indicate your conversion factors for each row in two different column, say, F and G, you could try something like this:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rAction As Range
    Set rAction = Range("B1:D99")
    Dim adyC As Long

    If Intersect(rAction, Target) Is Nothing Then Exit Sub
    If Target.Count > 1 Then Exit Sub
    Application.EnableEvents = False

    adyC = Target.Column

    If adyC = 2 Then
        Target.Offset(0, 1).Value = Target.Value / Target.Offset(0, 4).Value
        Target.Offset(0, 2).Value = Target.Offset(0, 1).Value / Target.Offset(0, 5).Value
    End If
    If adyC = 3 Then
        Target.Offset(0, -1).Value = Target.Value * Target.Offset(0, 3).Value
        Target.Offset(0, 1).Value = Target.Value / Target.Offset(0, 4).Value
    End If
    If adyC = 4 Then
        Target.Offset(0, -1).Value = Target.Value * Target.Offset(0, 3).Value
        Target.Offset(0, -2).Value = Target.Offset(0, -1).Value * Target.Offset(0, 2).Value
    End If

    Application.EnableEvents = True

End Sub