Correcting a Run-time error ‘445’ problem

I'm trying to modify an Excel 2003 macro that will open a workbook in a folder, print it, close that workbook, open another one and keep printing and closing workbooks in the folder until they're all printed. I know I can no longer use "Set fs = Application.FileSearch" in Excel 2010, but I don't know or understand the alternatives. The macro I used before the change to 2010 is listed below. I would appreciate it if someone could show me how to replace the "Set fs = Application.FileSearch" with the new and accepted alternative. Thanks in advance! JPDutch

Sub Print3()
'
' MacroGRP2 Macro
' Macro recorded 01/06/2012 by jpdutch
'
' This starts the print job
    Dim fs As FileSearch
    Dim i As Integer
    Dim wbk As Workbook

    Set fs = Application.FileSearch

    With fs
        .LookIn = ThisWorkbook.Path
        .Filename = "*.xls"
    For i = 200 To .Execute()
        Set wbk = Workbooks.Open(.FoundFiles(i))
'   This will print the document
         ActiveWorkbook.PrintOut Copies:=1, Collate:=True
'   Wait
        newHour = Hour(Now())
        newMinute = Minute(Now())
        newSecond = Second(Now()) + 7
        waitTime = TimeSerial(newHour, newMinute, newSecond)
        Application.Wait waitTime
    wbk.Close SaveChanges:=True
    Next i
End With
End Sub

This should work, although it displays as "running" after it finished everything... not sure why. Any feedback appreciated.

edit: please note that the macro doesn't print out the workbook in which you store the code.

Sub Print3()
'
' MacroGRP2 Macro
' Macro recorded 01/06/2012 by jpdutch
' Macro altered 01/22/2013 for Excel 2007 compatibility
'
' This starts the print job
Dim waitTime, newHour, newMinute, newSecond
Dim Wbk As Workbook
Dim MyPath As String
Dim MyFile As String

MyPath = ThisWorkbook.Path
MyFile = Dir(MyPath & "\" & "*.xls")

Do While MyFile <> ""
    If MyFile <> ThisWorkbook.Name Then
        Set Wbk = Workbooks.Open(MyPath & "\" & MyFile)
'       This will print the document
        Wbk.PrintOut copies:=1, collate:=True
'           Wait
            newHour = Hour(Now())
            newMinute = Minute(Now())
            newSecond = Second(Now()) + 7
            waitTime = TimeSerial(newHour, newMinute, newSecond)
            Application.Wait waitTime
        Wbk.Close False
    End If
    MyFile = Dir
Loop
End Sub