Need help Converting Code to Read Alpha Numeric Legends instead of single character legend

This code below automates a process for me with single digit characters 0 through 9 and A through Z legends. I would now like it to work with Legends which are Just Letters Alone or Letters accompanied by a number. So For Example Legend "OVRV1" in the current code would read the legends as O, V, R, V, 1. The way the new code would behave would read it as O,V,R, V1
Legends are an alphabet letter alone or an alphabet accompanied by a letter. It should understand that V1 is not V even though V is contained in V1. Any Help Would be Great.

Including a file below which should explain what the macro currently does and what i need it to do , this should help clear out any issues. The Code below is the original code.

It should be noted the code pulls legends verbiage from its corresponding Legend in Column B. If the Legend has a Dash in it for example ORV-D1H the legends D,1, and H pull verbiage from the orange area and the O, R V Legends from the Light Green Area. Running the macro in the example file will clear any confusion.

Sub singletest() 
Dim colEnd As Long, r As Range, n As Integer, k As Integer
colEnd = Cells(1, 3).End(xlToRight).Column
Application.ScreenUpdating = False
Application.CutCopyMode = False
For Each r In Range("c1").Resize(, colEnd - 2)
    a = Split(r.Value, "-")
    For n = 0 To UBound(a)
        For k = 1 To Len(a(n))
            With Columns(1)
                Set c = .Find(Mid(a(n), k, 1), , , 1)
                    If Not c Is Nothing Then
                        f = c.Address
                        Do
                            If n > 0 Then
                                If c.Interior.Color = RGB(255, 192, 0) Then
                                    c.Offset(, 1).Copy Cells(c.Row, r.Column)
                                End If
                            Else
                                If c.Interior.Color <> RGB(255, 192, 0) Then
                                    c.Offset(, 1).Copy Cells(c.Row, r.Column)
                                End If
                            End If
                        Set c = .FindNext(c)
                        Loop Until f = c.Address
                    End If
            End With
        Next
    Next
Next
Application.CutCopyMode = True
Application.ScreenUpdating = True
MsgBox "Copying has been completed", vbInformation, "Done!"
End Sub

So
ORV2N-WABH is read as O, R, V2, N, W, A, B, H
And
ORVPRST-AB1H2FE is read as O, R, V, P, R, S , T, A, B1, H2, F, E?

I feel like I am missing something,

Hello donnydorko,

I have added the macro below to the attached workbook. Check it out and let me know if anything needs adjusting.

Sub ParseLegend()

    Dim cont As Integer
    Dim DataRows As Variant
    Dim Dict As Object
    Dim Key As Variant
    Dim Item As Variant
    Dim LegendCodes As Range
    Dim Matches As Object
    Dim n As Long, r As Variant
    Dim RegExp As Object
    Dim Result As String
    Dim Rng As Range
    
    
        Set Rng = Range("A1").CurrentRegion
        
        
          ' Create a lookup array to return the row number or numbers for a Legend.
            Set Dict = CreateObject("Scripting.Dictionary")
            Dict.CompareMode = vbTextCompare
            
            For Each Cell In Rng.Columns(1).Cells
                Key = Trim(Cell)
                Item = Cell.Row
                If Key <> "" Then
                    If Not Dict.Exists(Key) Then
                        ReDim DataRows(0)
                        DataRows(0) = Item
                        Dict.Add Key, DataRows
                    Else
                        DataRows = Dict(Key)
                        n = UBound(DataRows) + 1
                        ReDim Preserve DataRows(n)
                        DataRows(n) = Item
                        Dict(Key) = DataRows
                    End If
                End If
            Next Cell
        
          ' Parse the Legends from the legend code.
            Set RegExp = CreateObject("VBScript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "[A-za-z]\d+|[A-Za-z]"
        
            Set LegendCodes = Rng.Offset(0, 2).Resize(1, Rng.Columns.Count - 2)
            
            For Each Cell In LegendCodes
                Set Matches = RegExp.Execute(Cell)
                
                For i = 0 To Matches.Count - 1
                    If Dict.Exists(CStr(Matches(i))) Then
                        For Each r In Dict(CStr(Matches(i)))
                            Cell.Offset(r - 1, 0) = Rng.Cells(r, 2).Value
                            Cell.Offset(r - 1, 0).Interior.Color = Rng.Cells(r, 2).Interior.Color
                        Next r
                    Else
                        cont = MsgBox("Legend Code " & Matches(i) & " Is Missing." & vbCrLf _
                        & "Do you want to continue?", vbExclamation + vbYesNo)
                        If cont = vbNo Then Exit Sub
                    End If
                Next i
            Next Cell
            
End Sub

Hello donnydorko,

Glad it works. If there is anything about the code you want explained, just ask.