search within text file and replace strings with variable number of characters

Hi folks
I want to do the following using VBA:
- find some numbers in a textfile and replace these numbers.
- I know the number of characters that shall be entered/ stored / placed into the text file
- but the numbers that shall be replaced can be of variable numbers of characters

The numbers that shall be replaced are in the same line as the line starting with the words "simulation results"
After this expression there are 4 numbers separated by a space. All these 4 numbers shall be replaced with other numbers.

For example
The line in text file: "simulation results 0.020 923 9832.2 93.22 BDV XYXS" should be replaced with
"simulation results 0.0666 2222 2 0 BDV XYXS"

since numbers of characters may vary it can also look like:
"simulation results 1 2132323.2 111.1111 11 BDV XYXS" should be replaced with
"simulation results 0.0666 2222 2 0.213 BDV XYXS"

I have several hundreds of these textfiles and want to change these using VBA - to give me more flexibility in my work.

I struggle to find out these issues.

Hope someone can guide me.

Thanks!

I guess I explained this not accurate.
The numbers that shall be replaced are unknown. So if I could use the replace function without refering to the numbers that shall be replaced it would have worked...

I assumed that I needed to do a search for the word "simulation results" and then search for the first space, then find somehow the first number, read the numbers of characters the first number consists of, then overwrite this number with the new number etc...

but how? or is there another way to it?

Try

Sub test()
    Dim myDir As String, fn As String, txt As String
    Const myReplace As String = "0.0666 2222 2 0 "
    myDir = ThisWorkbook.Path & "\"  '<-- folder path
    fn = Dir(myDir & "*.txt")
    Do While fn <> ""
        txt = CreateObject("Scripting.FileSystemObject") _
        .OpenTextFile(myDir & fn).ReadAll
        With CreateObject("VBScript.RegExp")
            .Global = True
            .MultiLine = True
            .Pattern = "^(simulation results )([\d\. ]+)"
            If .test(txt) Then
                txt = .Replace(txt, "$1" & myReplace)
            End If
        End With
        Open Replace(fn, ".txt", "_Updated.txt") For Output As #1
            Print #1, txt
        Close #1
        fn = Dir
    Loop
End Sub