Search and Replace words in bold

[moochie]

Hi there,
I am looking for a "search and replace routine", that takes all the word that are in bold and puts || around it.
Bold word ---> |Bold word| - does anyone know how I can do that?

Your help will truely be appreciated

Moochie

[Leith Ross]

Hello moochie,

Welcome to the Forum!
Are you looking for a single word or phrase in bold type or are you looking in phrases for words in that are bold type?

Word
These words are in bold.

OR

Some of these words are in bold.

[moochie]

Hi Leith,
Words in bold.

Ex. "Helenio Herrera Gavilán" should be changed to "|Helenio| Herrera |Gavilán|"

[Leith Ross]

Hello moochie,

These words are in worksheet cells, yes?

[moochie]

Yes they are in cells.

[shg]

One way -- select the cells of interest and run this:

Sub Bold()
    Dim cell As Range
    Dim iPos As Long
    Dim sText As String
    
    For Each cell In Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues)
        sText = " " & cell.Value
        iPos = 0
        
        Do
            iPos = InStrRev(sText, " ", iPos - 1)
            If cell.Characters(iPos, 1).Font.Bold Then
                cell.Characters(iPos, 0).Insert "|"
            End If
            
            If cell.Characters(iPos - 2, 1).Font.Bold Then
                cell.Characters(iPos - 1, 0).Insert "|"
            End If
        Loop While iPos > 1
    Next cell
End Sub

EDIT: I wouldn't expect it to be fast -- there's a lot of readin' and writin' the worksheet.

[moochie]

Thank you for the help.
I have one small problem left.

Som of the my words are half bold and half regular font. ( Like this Community).
I think the script checks for space, because i does not put the "|" in the these words.

Words like "Community" end up like "Community|" and they should end up like this "|Com|munity"

Could you help me with that?

[shg]

That doesn't seem to agree with bold words, but OK:

Sub Bold()
    Dim cell        As Range
    Dim i           As Long
    Dim bBoldIs     As Boolean
    Dim bBoldWas    As Boolean

    For Each cell In Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues)
        bBoldWas = False
        For i = Len(cell.Value) To 2 Step -1
            bBoldIs = cell.Characters(i, 1).Font.Bold
            If bBoldIs Xor bBoldWas Then
                cell.Characters(i + 1, 0).Insert "|"
                If bBoldIs Then cell.Characters(i + 1, 1).Font.Bold = False
            End If
            bBoldWas = bBoldIs
        Next i
        
        If cell.Characters(1, 1).Font.Bold Then
            cell.Characters(1, 0).Insert "|"
            cell.Characters(1, 1).Font.Bold = False
        End If
    Next cell
End Sub