Macro to copy specific entries and adjust value based on a table

How about

Sub MoveData()
    Dim destSht As Worksheet: Set destSht = Sheets("Export")
    Dim srcSht As Worksheet: Set srcSht = Sheets("Import")
    Dim srcLR As Long: srcLR = srcSht.Range("A" & Rows.Count).End(xlUp).Row

    Application.ScreenUpdating = False
    With destSht
        .Columns("A:E").Clear
    End With
    With srcSht
            .Range("F1").Value = "Hdr"
        With .Range("F2:F" & srcLR)
            .FormulaR1C1 = "=INDEX('Adjustment Table'!R4C2:R6C2,MATCH(RC[-2],'Adjustment Table'!R4C1:R6C1,0))+RC[-1]"
            .Value = .Value
            .AutoFilter Field:=1, Criteria1:=">0"
            .Offset(1).EntireRow.Copy Destination:=destSht.Range("A2")
            .AutoFilter
        End With
        .Range("F:F").ClearContents
    End With
    With destSht
        .Columns(6).Copy Destination:=.Columns(5)
        .Range("A1").Resize(, 5) = Array("Number", "Date", "Name", "Name", "Value")
        .Columns(6).Delete
        .Range("A:E").Columns.AutoFit
    End With
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
End Sub

You could use something along these lines.

Option Explicit

Sub copyData()
Dim wsI As Worksheet, wsAT As Worksheet, wsEx As Worksheet
Dim matchRng As Variant
Dim k As Long, adjV As Double
Dim resRng As Range, rs As Range
Set wsI = Worksheets("Import")
Set wsAT = Worksheets("Adjustment Table")
Set wsEx = Worksheets("Export")

matchRng = Application.Index(Application.Transpose(wsAT.Range("A4:B" & wsAT.Cells(Rows.Count, "B").End(xlUp).Row)), 0, 0)
For k = LBound(matchRng, 2) To UBound(matchRng, 2)
    Set resRng = Find_Range(matchRng(1, k), wsI.Columns("D"), xlValues, xlWhole)
    If Not resRng Is Nothing Then
        For Each rs In resRng
            wsI.Range("A" & rs.Row).Resize(, 5).Copy wsEx.Range("A" & wsEx.Cells(Rows.Count, "A").End(xlUp).Row + 1)
            adjV = wsEx.Range("E" & wsEx.Cells(Rows.Count, "E").End(xlUp).Row)
            adjV = adjV + (adjV * matchRng(2, k))
            wsEx.Range("E" & wsEx.Cells(Rows.Count, "E").End(xlUp).Row) = adjV
        Next
    End If
Next
End Sub

Function Find_Range(Find_Item As Variant, _
    Search_Range As Range, _
    Optional LookIn As Variant, _
    Optional LookAt As Variant, _
    Optional MatchCase As Boolean) As Range
    Dim c As Range, firstAdd As String
    If IsMissing(LookIn) Then LookIn = xlValues 'xlFormulas
    If IsMissing(LookAt) Then LookAt = xlPart 'xlWhole
    If IsMissing(MatchCase) Then MatchCase = False
    With Search_Range
        Set c = .Find( _
        What:=Find_Item, _
        LookIn:=LookIn, _
        LookAt:=LookAt, _
        SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=MatchCase, _
        SearchFormat:=False)
        If Not c Is Nothing Then
            Set Find_Range = c
            firstAdd = c.Address
            Do
                Set Find_Range = Union(Find_Range, c)
                Set c = .FindNext(c)
            Loop While c.Address <> firstAdd
        End If
    End With
End Function

See attached workbook

It was only a coincidence that it sorted by Name as your workbook was sorted. I added an extra sub to sort however I was not sure which column was Store - I assumed column C was store so you will need to adjust sort macro as required. I added code to clear the output from Export sheet prior to data being copied across as well. See attached workbook V2.