Macro to open and close all files in a folder and sub folders

**BillDoor** · 12-21-2012, 05:35 AM

Hi

I have the following to open all files in a specific folder

Formula:

Sub OpenAll() 

    Dim path As Variant 

    Dim excelfile As Variant 

    path = "\\example\1 January\" 

     

    excelfile = Dir(path & "*.xlsx") 

 

    Do While excelfile <> "" 

        Workbooks.Open Filename:=path & excelfile 

        excelfile = Dir 

    Loop 

End Sub

But want I really need is for it to also look in the sub folders and open all those too, I also would like for it to then close them all.

Is this something that can be done?

thanks

**JBeaucaire** · 12-22-2012, 05:25 AM

Like so, you need a macro to feed in a folder path to the main macro which opens all the files in that path, then searches for folders IN that path and calls itself again, deeper and deeper recursively until it runs out of files/folders. This also shows you one way to close the files you've opened.

Option Explicit

Sub LoopStarter()
    Call Looper("\\example\1 January\")             'put initial folder here to initiate
End Sub


Private Sub Looper(sSourceFolder As String)
'This will loop into itself, first processing the files in the folder
'then looping into each subfolder deeper and deeper until all folders processed
Dim Fldr As Object, SubFldr As Object, fNAME As String

fNAME = Dir(sSourceFolder & "*.xlsx")               'get first file from folder

Do While Len(fNAME) > 0                             'do this loop if file is found
    Workbooks.Open sSourceFolder & fNAME, True      'opens found file, updates links
    ActiveWorkbook.Close True                       'closes opened file, saving changes

    fNAME = Dir                                     'get next file from same folder
Loop

'start looping deeper into same folder looking for more files
Set Fldr = CreateObject("scripting.filesystemobject").Getfolder(sSourceFolder)
For Each SubFldr In Fldr.SubFolders
    Looper SubFldr.path & "\"             'calls this same macro again with new deep folder
Next

End Sub

**BillDoor** · 12-24-2012, 06:02 AM

Hi JBeaucaire
Thanks for this, but it doesn't seem to go through the sub-folders, it will cycle through and Excel fils in the top level, but doesn't seem to go into the sub levels

The set up is around 4 sub folders with about 10 files in each, there are no other sub folders lower down, these 4 all sit in the original top level

**JBeaucaire** · 12-24-2012, 11:42 AM

It appears the sub loops were not including the final "/" in the path string, so I added a tweak above in the code to fix that. Tested and working on my system.