Search Cell Value Delete if Not in Named Range

I am pretty new to VBA I am basically trying to search all the cell values in column K of multiple sheets. If the value in column K is not found in my named range I want it to delete the entire row. Any help is greatly appreciated!!!!

Sub Delete()
    
If ActiveSheet.Name = "Tracking System Compliance" Then
Range("J:J").Select

Else: Range("K:K").Select
End If

'need code here to delete the values not found in the named range "tabmodels"

        If Not c Is Nothing Then c.EntireRow.Delete
    Loop While Not c Is Nothing
End Sub

1. What is your named Range called and what sheet is it on?
2. Exactly which sheets do you want to compare column K to the named Range?
3. Do you want to delete the row of column K when it does not match anything in the named range OR do you want to delete the row of the named range if it does not match anything in column K?
4. Are there any other sheets that will have nothing to do with this? (dont want to set a macro to work across all sheets if it needs to be specific)

Originally Posted by stnkynts

1. What is your named Range called and what sheet is it on?
2. Exactly which sheets do you want to compare column K to the named Range?
3. Do you want to delete the row of column K when it does not match anything in the named range OR do you want to delete the row of the named range if it does not match anything in column K?
4. Are there any other sheets that will have nothing to do with this? (dont want to set a macro to work across all sheets if it needs to be specific)

1. The named range is called "TABMODELS"
2. Sheet3 i want to compare column J to the named range, Sheet4 & Sheet5 I want to compare column K to the named range.
3. I want to delete the row of column K/J when it does not match anything in the named range.
4. There are other sheets in the workbook, so it does have to be sheet specific.

Originally Posted by stnkynts

Sub Delete()
Dim ws1 As Worksheet:   Set ws1 = Sheets("Sheet1")
Dim iFind As Range
Dim lastrow As Long, wksht As Long, icell As Long

Application.ScreenUpdating = False

For wksht = 4 To 5
    lastrow = Sheets(wksht).Range("K" & Rows.Count).End(xlUp).Row
    For icell = lastrow To 1 Step -1
        Set iFind = ws1.Range("TABMODELS").Find(What:=Sheets(wksht).Range("K" & icell).Value, _
            LookIn:=xlValues, LookAt:=xlWhole)
                If iFind Is Nothing Then
                    Sheets(wksht).Range("K" & icell).EntireRow.Delete Shift:=xlUp
                End If
    Next icell
Next wksht

lastrow = Sheets("Sheet3").Range("J" & Rows.Count).End(xlUp).Row
For icell = lastrow To 1 Step -1
    Set iFind = ws1.Range("TABMODELS").Find(What:=Sheets("Sheet3").Range("J" & icell).Value, _
            LookIn:=xlValues, LookAt:=xlWhole)
                If iFind Is Nothing Then
                    Sheets("Sheet3").Range("K" & icell).EntireRow.Delete Shift:=xlUp
                End If
Next icell

Application.ScreenUpdating = True

End Sub

Is there anyway to make this stop deleting at row 3 on sheet 3, 4, & 5? I have headings in row 1 & 2 on sheet3, sheet4, and sheet5 and don't want to delete those rows. Otherwise it works great!

Sub Delete()
Dim ws1 As Worksheet:   Set ws1 = Sheets("Sheet1")
Dim iFind As Range
Dim lastrow As Long, wksht As Long, icell As Long

Application.ScreenUpdating = False

For wksht = 4 To 5
    lastrow = Sheets(wksht).Range("K" & Rows.Count).End(xlUp).Row
    For icell = lastrow To 3 Step -1
        Set iFind = ws1.Range("TABMODELS").Find(What:=Sheets(wksht).Range("K" & icell).Value, _
            LookIn:=xlValues, LookAt:=xlWhole)
                If iFind Is Nothing Then
                    Sheets(wksht).Range("K" & icell).EntireRow.Delete Shift:=xlUp
                End If
    Next icell
Next wksht

lastrow = Sheets("Sheet3").Range("J" & Rows.Count).End(xlUp).Row
For icell = lastrow To 3 Step -1
    Set iFind = ws1.Range("TABMODELS").Find(What:=Sheets("Sheet3").Range("J" & icell).Value, _
            LookIn:=xlValues, LookAt:=xlWhole)
                If iFind Is Nothing Then
                    Sheets("Sheet3").Range("K" & icell).EntireRow.Delete Shift:=xlUp
                End If
Next icell

Application.ScreenUpdating = True

End Sub

Ah, you are genius! Thanks so much for your help! You just saved me tons of manual effort every month!