Insert jpg image from file path to image frame

Morning all,

I am tearing my hair out with this one.

I have a list of images saved on a server named 0001.jpg, 0002.jpg, 0003.jpg etc... etc...
The file path for these images is P:\Sales\Images\Nov 12

I have created a spreadsheet with a combo box (Sheet 1) that lists the image numbers and these are linked to cell A6. I have created a CONCATENATE formula in cell A7 so that it reads 0001.jpg etc...

I have also added an ActiveX Image control (Image 1) to the spreadsheet.

What I would like is for the user to select the image name from the combo box and for the image to be displayed in the Image control.

There must be a fairly easy way of doing this - but it's driving me crazy. Any help would be greatly appreciated.

Apologies, I can't upload a sample document as my company's firewall seems to be blocking it.

Thanks

Steve

Not the full solution, but at its simplest see if you can adapt the following line:

Me.Image1.Picture = LoadPicture("C:\path\to\image.jpg")

Try this, it should load the picture, when you make a selection from the combobox.

Private Sub ComboBox1_Change()

Image1.Picture = LoadPicture("C:\Dave's Pictures\" & ComboBox1 & ".jpg")

End Sub

Edit folder location.

How are you populating the combo box? It doesn't make sense from a user POV to populate the combo box with image numbers which don't exist. Use a Dir function loop to populate the combo box with .jpg's which exist in the folder. Otherwise don't use error handling if it can't find an image, instead try:

Private Sub ComboBox1_Change()
    Dim imageFileName As String
    
    imageFileName = imageFolder & Range("A7").Value
    If Dir(imageFileName) <> "" Then
        Me.Image1.Picture = LoadPicture(imageFileName)
        Range("A8").Clear
    Else
        Me.Image1.Picture = Nothing
        Range("A8").Value = "Image " & imageFileName & " is not available"
    End If
    
End Sub

where imageFolder is a string containing the folder path.

You can add a comand button to the sheet and use this code to populate the combobox with just .jpg files in the folder.

Private Sub CommandButton1_Click()
    Dim MyFile As String, MyDir As String
    'change the address to suite
    MyDir = "C:\Dave's Pictures\"
    MyFile = Dir(MyDir & "*.jpg")    'change file extension

    ChDir MyDir
    Do While MyFile <> ""
        ComboBox1.AddItem MyFile
        MyFile = Dir()
    Loop

End Sub

Then in the combobox xhange use this code

Private Sub ComboBox1_Change()

Image1.Picture = LoadPicture(ComboBox1)

End Sub

If you have revised the properties of the combobox1, it may be best just to delete the combobox and draw another. Then change the code to whatever combobox number it is.