delete entire row if 'value' found anywhere in column - most efficient way?

Ive got the code below doing what i want, which is to delete an entire row if 'Unsettled' is found anywhere in a particular column.

Is there a more efficient way to do this when the number of rows is large?

Dim Counter As Long

Cells(2,colNum).Select    ' Starting point, row 2 in column 'colNum'

 For Counter = 1 To 25000     ' need to change 25000 to lastRow later
  If ActiveCell.Value Like "Unsettled" Then
   ActiveCell.EntireRow.Delete     ' Delete Row if 'Unsettled' is found in colNum
    Else
     ActiveCell.Offset(1, 0).Select     ' Move down a row
      End If
  Next Counter

Give this a try

Sub del_unwantedRows()
Const WhatColumn As String = "A" '<== Change to the column that contains Unsettled
Dim RangeToDelete As Range
Dim lastrow As Long, Ptr As Long
    
    lastrow = Cells(Rows.Count, WhatColumn).End(xlUp).Row
    For Ptr = 1 To lastrow
        If Cells(Ptr, WhatColumn) Like "*Unsettled*" Then
            If RangeToDelete Is Nothing Then
                Set RangeToDelete = Cells(Ptr, WhatColumn)
            Else
                Set RangeToDelete = Union(RangeToDelete, Cells(Ptr, WhatColumn))
            End If
        End If
    Next Ptr
    If Not RangeToDelete Is Nothing Then
        RangeToDelete.EntireRow.Delete
    End If
End Sub

Thats where i was headed, thanks Mike.

However, what i was asking was not this, but... is there a more efficient way to perform this task than going down the column cell by cell.

For example, in vba, would filtering and deleting the visible cells be quicker?
Or is there a completely different approach that is more efficient on resources/time to run.
The reason i ask is that i may have upto 30000 rows to process and may be performing the routine multiple times daily.

The solution I gave would be way faster then what you have. Yes you can delete filtered rows, but I believe you would need to sort that column first then filter the data and delete. Specialcells(xlCellTypeVisible) is funny when dealing with very large amount of rows.

true, forgot 'special cells visible' can be funny at times, thanks.
the question remains as to whether your improved method (cheers for that!) is 'optimal'?
this part is a small part of a much larger process which is taking too long so need to optimise all parts so the sum is faster.

ok, for test purposes (time to run)....im going to use this...

' Start the Timer
start_time = Now()

'''''''''''''''' 
'Production code here
'''''''''''''''

'Stop the Timer
end_time = Now()
 
Application.StatusBar = "Completed calculations. Time taken: " & (DateDiff("s", start_time, end_time) & " seconds")

Would be good to get more methods to test though.