Excel 2003 / 2010 compatibility

Hi!
I have worked out a code which is able to take a picture of a chart with a table below and export it as a picture! However, it only works on Excel 2003.... In Excel 2010 it doesn't work... :-(
I get this error on "Selection.CopyPicture Appearance:=xlScreen, Format:=xlBitmap":
Run-time error '1004'
Application-defined or object-defined error

Any help is very much appreciated!!
Best regards

is the table part of the chart or a range below it? the code ought to work as far as I can tell

Hi.
Thanks for the reply.
The table is not part of the chart, so I'm selecting a range including a chart AND the tables below.

The code looks like this:

Sub export_figures()
Dim folder_name As String
folder_name = Sheets("MONTHLY REPORT + TCM TEMPLATE").Range("S25")
Application.ScreenUpdating = True
Sheets("MONTHLY REPORT + TCM TEMPLATE").Range("A1:O45").Select
Hi = Selection.Height
Wi = Selection.Width
' FOR SOME REASON THE CODE BELOW ONLY WORKS IN EXCEL 2003
Selection.CopyPicture Appearance:=xlScreen, Format:=xlBitmap

Set ch = ActiveSheet.ChartObjects.Add(0, 0, Wi, Hi)
ch.Name = "Production Chart"
ch.Chart.Paste
ch.Chart.Export Filename:=folder_name & "\Production.png", FilterName:="PNG"

Best regards,

asgersax,

Welcome to the forum.

I have added code tags to your post. As per forum rule 3, you need to use them whenever you put any code in your post. Please add them in future. If you need more information on how to use them, check my signature below this post.

the code is fine since it works in 2010 for me. can you post the workbook-just that sheet and the code necessary

that workbook works fine here-are you using 32bit or 64bit excel?

64 bit windows but 32bit excel

does the problem remain if you use

Selection.CopyPicture Appearance:=xlPrinter, Format:=xlBitmap

or

Selection.CopyPicture Appearance:=xlScreen, Format:=xlPicture

or

Selection.CopyPicture Appearance:=xlPrinter, Format:=xlPicture

which line of code did you use in the end?

isn't that the line you had originally that didn't work?

does this work any better?

Sub export_figures()
   Dim folder_name            As String
   Dim wsRpt                  As Worksheet
   Dim wsCharts               As Worksheet
   Dim oShp                    As Shape
   Dim ch                     As Chart
   Dim vNames
   Dim vRanges
   Dim n                      As Long

   vRanges = Array("A1:O45", "A50:P104", "A106:P165")
   vNames = Array("Production", "Injection", "Deferred")
   Set wsRpt = ThisWorkbook.Sheets("MONTHLY REPORT + TCM TEMPLATE")

   folder_name = wsRpt.Range("S25").Value
   
   Set wsCharts = Worksheets.Add
   Set oShp = wsCharts.Shapes.AddChart(xlColumn, 0, 0, 10, 10)
   Set ch = oShp.Chart
   
   Application.ScreenUpdating = True
   For n = LBound(vRanges) To UBound(vRanges)

      With wsRpt.Range(vRanges(n))
         oShp.Height = .Height
         oShp.Width = .Width
         .CopyPicture Appearance:=xlScreen, Format:=xlBitmap
      End With

      With ch
         .Paste
         .Export Filename:=folder_name & "\" & vNames(n) & ".png", FilterName:="PNG"
         .ChartArea.ClearContents
      End With
   Next n
   Application.DisplayAlerts = False
   wsCharts.Delete
   Application.DisplayAlerts = True
End Sub