cleaner code

I created this macro that copies from cell A1 and paste into the next cell I want to keep incrementing but I dont want to keep copy and paste the same thing how can I make it cleaner, with out having next_1, next _2 , next_3 and so on

Sub Macro1()
'
' Macro1 Macro
'

'
    Range("A1").Select
    Selection.Copy
    Range("A4").Select
    ActiveSheet.Paste
    Application.OnTime Now + TimeValue("00:01:00"), "next_1"
    End Sub
    
Sub next_1()
    Range("A1").Select
    Selection.Copy
    Range("A5").Select
    ActiveSheet.Paste
    Application.OnTime Now + TimeValue("00:01:00"), "next_2"
End Sub

Sub next_2()
    Range("A1").Select
    Selection.Copy
    Range("A6").Select
    ActiveSheet.Paste
    Application.OnTime Now + TimeValue("00:01:00"), "next_3"
End Sub

Sub next_3()
    Range("A1").Select
    Selection.Copy
    Range("A7").Select
    ActiveSheet.Paste
End Sub

I had it before every 10sec just for testing,

Not sure maybe this?

    Range("a1").Copy Range("a4")
    Range("a4").AutoFill Range("a4:a8"), xlFillSeries

In a standard module:

Option Explicit

Public tRun As Date

Sub Macro1()
    Static iRow   As Long

    If tRun = 0 Then
        iRow = 4
    End If

    With Range("A1")
        .Copy .Offset(iRow - 1)
    End With

    iRow = iRow + 1
    tRun = Now() + #12:00:10 AM#
    Application.OnTime Earliesttime:=tRun, _
                       Procedure:="Macro1", _
                       Schedule:=True
End Sub

In ThisWorkbook:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.OnTime Earliesttime:=tRun, _
                       Procedure:="Macro1", _
                       Schedule:=False
End Sub

I feel kinda embarrassed to ask, but I been trying for a while to add the time stamp on the A column for every print with no luck, how can it be done ? I had put =now() on A3 cell and change Range("A3:D3") but it copies the now() so the time is the same for every row

Option Explicit

Public tRun As Date

Sub Macro1()
    Static iRow   As Long
    
    If tRun = 0 Then iRow = 5

    With Range("B3:D3")
        .Copy .Offset(iRow - 1)
    End With
    

        iRow = iRow + 1
    tRun = Now() + #12:00:10 AM#
    Application.OnTime Earliesttime:=tRun, _
                       Procedure:="Macro1", _
                       Schedule:=True
End Sub

Clipboard01.jpg

Option Explicit

Public tRun As Date

Sub Macro1()
    Static iRow   As Long   ' initial row to copy to
    
    If tRun = 0 Then iRow = 5

    Range("A3").Value = Now()
    With Range("A3:D3")
        .Copy .Offset(iRow - .Row)
    End With
    

    iRow = iRow + 1
    tRun = Now() + #12:00:10 AM#
    Application.OnTime Earliesttime:=tRun, _
                       Procedure:="Macro1", _
                       Schedule:=True
End Sub

If that takes care of your original query, please select Thread Tools from the menu above and mark the thread as solved. Thanks.

A little better:

    If tRun = 0 Then iRow = 5

    With Range("A3:D3")
        .Cells(1).Value = Now()
        .Copy .Offset(iRow - .Row)
    End With