Dir function question

I would like to iterate through folders. I'm attempting to do so using the dir function. Here is the code I tried:

FolderName = Dir(PathName, vbDirectory)                                   

Do While FolderName <> ""

        MsgBox("FolderName = " & FolderName)

        'Other code will eventually go here
           
        FolderName = Dir()                                              

Loop

I can't understand why the first two FolderName strings that are displayed with MsbBox are "." and ".." (one period and then two periods) before it even gets to the first folder name.

Also, it not only returns the desired folder names but also the names of the Excel workbooks that are in the same main folder. How do I get the dir function to only return folder names?

Will this do the trick?

FolderName = Dir(PathName, vbDirectory)                                   

Do until FolderName = ""
        MsgBox("FolderName = " & FolderName)

        'Other code will eventually go here
           
        FolderName = Dir()                                              

Loop

No, that didn't change anything.

"." and ".." are standard DOS folder 'shortcuts'. Type in DIR in a command window and you will see them. "." is the current directory and ".." is the parent directory. In VBA, use an If statement to ignore them and GetAttr to check if the file returned by Dir is a directory:

Sub List_Subfolders()

    Dim folder As String
    Dim fileName As String
    
    folder = "C:\Windows\"
    If Right(folder, 1) <> "\" Then folder = folder & "\"
    
    fileName = Dir(folder, vbDirectory)
    Do While fileName <> ""
        If fileName <> "." And fileName <> ".." Then
        
            'Make sure it's a directory
            If (GetAttr(folder & fileName) And vbDirectory) = vbDirectory Then
                MsgBox folder & fileName
            End If

        End If
        fileName = Dir
    Loop

End Sub

Originally Posted by Chippy

"." and ".." are standard DOS folder 'shortcuts'. Type in DIR in a command window and you will see them. "." is the current directory and ".." is the parent directory. In VBA, use an If statement to ignore them and GetAttr to check if the file returned by Dir is a directory:

Thanks. That did the trick.