Code to work on rows 9-220 only

**Grf** · 10-12-2012, 05:24 AM

Hi Everyone,
This is my first post so please go easy on me!

Private Sub Worksheet_Change(ByVal Target As Range)
Range("A" & ActiveCell.Row) = Date
End Sub

The above code works fine to place a date stamp in column A of any row I input numeric data into however I now wish to restrict this activity to rows 9-220. Can anyone assist me with this please?
Regards
Grf

**arlu1201** · 10-12-2012, 05:35 AM

Assuming that you are inputting your data in column B, try this -

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("B9:B220")) Is Nothing Then
    Range("A" & Target.Row) = Date
End If
End Sub

**JosephP** · 10-12-2012, 05:39 AM

to cover entire rows

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rcell                 As Range
    On Error GoTo error_handler
    If Not Intersect(Target, Range("9:220")) Is Nothing Then
        Application.EnableEvents = False
        For Each rcell In Intersect(Target, Range("9:220")).Cells
            Range("A" & rcell.Row) = Date
        Next rcell
        Application.EnableEvents = True
    End If
    Exit Sub
error_handler:
    Application.EnableEvents = True
End Sub

**Grf** · 10-12-2012, 05:49 AM

Thanks JP , yes I am actually using C9:Y220, so I will incorporate that in your code. Regards grf

**Grf** · 10-12-2012, 05:42 AM

Thank you very much Arlette, it works perfectly
Regards Graham

**arlu1201** · 10-12-2012, 05:46 AM

If you are satisfied with the solution(s) provided, please mark your thread as Solved.

Select Thread Tools-> Mark thread as Solved. To undo, select Thread Tools-> Mark thread as Unsolved.