Exporting data from on sheet across entire workbook

**elinyc86** · 10-05-2012, 05:24 PM

I need to distribute the daily dollar amount for each merchant from "DAILY DEPOSITS" onto each merchants individual sheet for that date.

On the daily DAILY DEPOSITS sheet, the date and amount is changed everyday.

For example on the "DAILY DEPOSITS" sheet ACCENT BRIDAL(C4) had $1.00(D4) for 10/06/12. I need this to be reflected on the "ACCENT BRIDAL" sheet showing a deposit of $1.00 for 10/06/12 in cell C98.

If anyone can give me any help on this I would highly appreciate it.

Thanks

**Leith Ross** · 10-05-2012, 11:26 PM

Hello ,

The macro below has been attached to a button on the "Daily Deposits". The attached workbook contains the button and the macro.

Sub RecordDeposits()

    Dim Cell As Range
    Dim DepDate As Range
    Dim Rng As Range
    Dim Wks As Worksheet
    
    
        Set Rng = Worksheets("Daily Deposits").ListObjects(1).DataBodyRange
        
            For Each Cell In Rng.Columns(2).Cells
            
                If Not IsEmpty(Cell) Then
                    On Error Resume Next
                        Set Wks = ThisWorkbook.Worksheets(Cell.Text)
                        
                        If Err = 9 Then
                            MsgBox "The worksheet '" & Cell.Text & "' was not found." & vbCrLf _
                                  & "Please check the spelling and spaces.", vbExclamation
                            Err.Clear
                        Else
                            Set DepDate = Wks.Columns(2)
                            Set DepDate = DepDate.Find(Cell.Offset(0, -1).Text, , xlValues, xlWhole, xlByRows, xlPrevious, False, False, False)
                            
                            If Not DepDate Is Nothing Then
                                DepDate.Offset(0, 3).Value = Cell.Offset(0, 1)
                            End If
                        End If
                    On Error GoTo 0
                    
                End If
            
            Next Cell
        
End Sub