run-time error '13' type mismatch visual basic

**Michell Feitosa** · 09-22-2012, 11:28 PM

Hello,

I'm a very beginner user of macros, and when a erro comes up, I have no idea how to fix it. Could you guys help me?

I have a macro to add row or delete rows to the table, and I'm using a message box to do it.
The problem is, when I select the option "Cancel" the "run-time error '13' " type mismatch, comes up. And when I degub it, the line " MyInput = InputBox(Msg, Title)" is selected in yellow.

how to fix it?

Sub AddDeleteRow()

ActiveSheet.Unprotect Password:="secret"
    
    Dim Msg, Title As String
    Dim MyInput As Integer
     ' Define message."
    Msg = "Would you like to Add or Delete last row? " _
    & vbNewLine & "Enter 1 to Add row" & vbNewLine _
    & "Enter 2 to Delete last row"
     
    Title = "Add or Delete last row" ' Define title.
    MyInput = InputBox(Msg, Title)
    Select Case MyInput
    Case 1
        MsgBox "Adding row"
        Range("A4").End(xlDown).ListObject.ListRows.Add AlwaysInsert:=False
    Case 2
        MsgBox "Deleting last row"
    End Select
    
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True, Password:="secret"

End Sub

Thanks in advance

Michell

**nilem** · 09-23-2012, 12:38 AM

try it

MyInput = Application.InputBox(Msg, Title, Type:=1)

**Michell Feitosa** · 09-23-2012, 06:28 AM

It was just brilliant Nilem.

Thank you so much.

By the way, Im struggling with the cod to delete the last row of my table, do you have any suggestion. It's going to be in the same macro above.

Michell

**nilem** · 09-23-2012, 08:13 AM

hi Michell, try something like this

Sub AddDeleteRow()
Dim MyInput As Integer
MyInput = Application.InputBox(Prompt:="Would you like to Add or Delete last row? " & vbNewLine _
                                       & "Enter 1 to Add row" & vbNewLine & "Enter 2 to Delete last row", _
                               Title:="Add or Delete last row", _
                               Default:=1, _
                               Type:=1)
If MyInput = 0 Then Exit Sub
With ActiveSheet.ListObjects(1)
    Select Case MyInput
        Case 1
            MsgBox "Adding row"
            .ListRows.Add
        Case 2
            MsgBox "Deleting last row"
            .ListRows(.ListRows.Count).Delete
    End Select
End With
End Sub