Application.Inputbox

**Hilton1982** · 09-14-2012, 05:34 AM

Hi Masters

I want to use an Application InPutBox that will ask the users to enter a password.
When the inputbox is = 0 and they press ok they should get a msgbox that tells them you should enter a password to continue.
When they press Cancel the Inputbox stop and not give me the same msgbox as mentioned above.

Any help will do?

Thanks and regards,
Hilton

**Andy Pope** · 09-14-2012, 05:53 AM

Sub X()

    Dim vntAnswer As Variant
    Dim lngAttempt As Long
    
    Do
        vntAnswer = Application.InputBox("Password")
        If vntAnswer = False Then Exit Sub
        
        lngAttempt = lngAttempt + 1
        If lngAttempt > 2 Then
            MsgBox "Too many tries", vbExclamation
            Exit Sub
        End If
        
    Loop While Len(vntAnswer) = 0
    
    MsgBox "Password is " & vntAnswer
    
    
End Sub

**Hilton1982** · 09-14-2012, 06:50 AM

Hi Andy,

Thank you for the Code it is working 100%.
Can you add the following step to the code if possible?

If the password is = 1010 Then
Run "Macro"
If Password <> 1010 Then
Msgbox = "incorrect password Retry or cancel", vbRetryCancel
If response = Retry
Goto Start
Else Exit Sub

**Andy Pope** · 09-14-2012, 08:07 AM

Sub X()

    Dim vntAnswer As Variant
    Const PWD = "1010"
    
        
    Do
        vntAnswer = Application.InputBox("Password")
        If vntAnswer = False Then Exit Sub
        
        If vntAnswer = PWD Then
            MsgBox "Go run my macro"
            Exit Sub
        End If
        
    Loop While MsgBox("Incorrect password Retry or Cancel", vbRetryCancel) = vbRetry
    
    
End Sub

**Hilton1982** · 09-14-2012, 08:38 AM

Thanks a million problem solved and now i can make the existing codes a lot shorter with this formality...

**Hilton1982** · 09-14-2012, 08:43 AM

Please help me with a easy code that will copy and paste data in the next empty row.

I have data fulled on the "Input" sheet then the macro copy and paste that onto to the record sheet however I want that to be copied everytime in the next empty row?

**Winon** · 09-14-2012, 08:52 AM

Hello Hilton1982,

Your last Post is way off the topic Re: Application.Inputbox. You should by right start a new thread.

Do you want to copy within the same sheet or from one to another?

**Hilton1982** · 09-14-2012, 09:02 AM

Winon from one to another

Sorry I will open a new Tread next time...

Thanks

**Winon** · 09-14-2012, 09:16 AM

This is the basics which should give you a start to tweak it the way you want it.

Sub Test()

Dim LR As Long
Dim r As Long

LR = Cells(Rows.Count, "A").End(xlUp).Row
    
Range("A2:A1000").EntireRow.Copy _
    Sheets("Sheet2").Range("A" & Sheets("Sheet2").Rows.Count).End(xlUp).Offset(1)


End Sub