Daniello1 - How to write a macro that would delete a sheet across multiple workbooks

I am creating this thread on behalf of new user Daniello1. He replied to an older thread located here: http://www.excelforum.com/excel-prog...html?p=2895634

That thread was for deleting all but one sheet in several workbooks. Daniello1's post in that thread:

Originally Posted by Daniello1

Hi Tigeravatar
I have the opposite problem - how to write a macro that would delete certain spreadsheet across multiple workbooks (this spreadheet has the same name on almost 1000 identical workbooks I have). Can you please advice?
Daniel

So he is asking how to delete a single specific sheet in multiple workbooks. Daniello1, give this try:

Sub WorksheetDeletionMacro_for_Daniello1()
    
    Const strSheetName As String = "Sheet1"
    
    Dim ws As Worksheet
    Dim strFldrPath As String
    Dim strFileName As String
    Dim strSep As String
    
    
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        If .Show = False Then Exit Sub  'Pressed cancel
        strFldrPath = .SelectedItems(1)
    End With
    
    strSep = Application.PathSeparator
    strFileName = Dir(strFldrPath & strSep & "*.xls*")
    
    With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
    End With
    
    Do While Len(strFileName) > 0
        With Workbooks.Open(strFldrPath & strSep & strFileName)
            If .Sheets.Count > 1 Then
                For Each ws In .Sheets
                    If LCase(ws.Name) = LCase(strSheetName) Then
                        ws.Delete
                        .Save
                        Exit For
                    End If
                Next ws
            End If
            .Close False
        End With
        strFileName = Dir
    Loop
    
    With Application
        .DisplayAlerts = True
        .ScreenUpdating = True
    End With
    
    Set ws = Nothing
    
End Sub