Code to send an e-mail. Don't send if attachment not found

Try this:

Option Explicit

Sub Send_Email()

    Dim OutApp As Object
    Dim OutMail As Object
    Dim ws As Worksheet
    Dim fileName As String, response As Integer

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")

    For Each ws In ActiveWorkbook.Worksheets
        If ws.Range("B9").Value Like "?*@?*.?*" Then
            fileName = ws.Range("F9").Value
            Set OutMail = OutApp.CreateItem(0)
            
            'On Error Resume Next
            With OutMail
                .To = ws.Range("B9").Value
                .CC = ws.Range("C9").Value
                .BCC = ""
                .Subject = ws.Range("D9").Value
                .HTMLBody = RangetoHTML(Sheets("Body").Range("A5:A19"))
                
                If Dir(fileName) <> "" Then
                    .Attachments.Add fileName
                    .send
                Else
                    response = MsgBox("File " & fileName & " not found." & String(2, vbCrLf) & _
                        "Do you want to send this email?", vbYesNo)
                    If response = vbYes Then .send
                End If
            
            End With
            'On Error GoTo 0

            Set OutMail = Nothing
        End If
    Next ws

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
    
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2010
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
 
    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         fileName:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    'Close TempWB
    TempWB.Close savechanges:=False
 
    'Delete the htm file we used in this function
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

I've included the complete code to reproduce your requirement. I wondered why you are using On Error Resume Next, as this shouldn't be necessary in this code. Therefore I've commented out that line and the On Error GoTo 0 statement.