Different number base system

I need a macro that will convert a number from decimal to binary, octave, and Hexadecimal.

and another to convert it back.

This conversion must take place between a variable and user form and back to the variable.

please help

Thanks

Search Excel help for the DEC2BIN(), OCT2BIN(), HEX2BIN(), etc. I'm pretty sure all those functions are built into Excel.

In excel on a spread sheet yes and also very easy.

In a macro with NO spreadsheet, that is not so easy to do.

VBA has built in functions which will convert to and from Octal and Hexadecimal numbers.

By Binary I assume you mean a binary representation string of 1s and 0s, because all numbers are binary in a computer.

If you googled the topic you would find a number of example codes already out there, such as:
http://www.devhut.net/2010/06/22/vba...al-and-binary/

Thanks Steven. This helps a lot. Now I must just learn how to use a functions.

It still leaves me with the octave and hexadecimal and my google searches does not seem to be as effective.

Sub TestHexAndOct()
    Dim n As Long, s As String
    
    n = 45
    s = n & " = Hex: " & Hex(n) & " and Oct: " & Oct(n) & vbCr
    s = s & "Hex: " & Hex(n) & " = " & Val("&H" & Hex(n)) & vbCr
    s = s & "Oct: " & Oct(n) & " = " & Val("&O" & Oct(n))
    MsgBox s
End Sub

You must add "&H" to a Hex string and "&O" to a Oct string. Other than that, it is fairly simple.

'http://www.devhut.net/2010/06/22/vba-converting-between-decimal-and-binary/
'Decimal To Binary
' =================
' Source: http://groups.google.ca/group/comp.lang.visual.basic/browse_thread/thread/28affecddaca98b4/979c5e918fad7e63
' Author: Randy Birch (MVP Visual Basic)
' NOTE: You can limit the size of the returned
'              answer by specifying the number of bits
Function Dec2Bin(ByVal DecimalIn As Variant, _
              Optional NumberOfBits As Variant) As String
    Dec2Bin = ""
    DecimalIn = Int(CDec(DecimalIn))
    Do While DecimalIn <> 0
        Dec2Bin = Format$(DecimalIn - 2 * Int(DecimalIn / 2)) & Dec2Bin
        DecimalIn = Int(DecimalIn / 2)
    Loop
    If Not IsMissing(NumberOfBits) Then
       If Len(Dec2Bin) > NumberOfBits Then
          Dec2Bin = "Error - Number exceeds specified bit size"
       Else
          Dec2Bin = Right$(String$(NumberOfBits, _
                    "0") & Dec2Bin, NumberOfBits)
       End If
    End If
End Function
 
'Binary To Decimal
' =================
Function Bin2Dec(BinaryString As String) As Variant
    Dim X As Integer
    For X = 0 To Len(BinaryString) - 1
        Bin2Dec = CDec(Bin2Dec) + Val(Mid(BinaryString, _
                  Len(BinaryString) - X, 1)) * 2 ^ X
    Next
End Function

Sub TestDecBin()
    MsgBox Dec2Bin(45) & " = " & Bin2Dec(Dec2Bin(45))
End Sub

I was looking for the easy solution. and it seems that CBase is the answer.

use it as any of the other functions like mid or len

variable2 = CBase(Variable1, 10, 2)      'for dec to bin

use
2 for binary
8 for octave
10 for decimal
16 for Hexadecimal

I was mistaken and in my trials inserted a Function called CBase and that is what made it work.

This Function works towards a spreadsheet

So. In other words. I still need help.

To convert number values to and from other base structures to decimal without the aid of a spreadsheet.

Thanks

You need the two functions which I posted earlier (Bin2Dec & Dec2Bin).
And it only works for base 2, 8, 10, & 16.

Function CBase(sNumber As String, nToBase As Long, nFromBase As Long) As String
    Dim nNumber As Long
    Select Case nToBase
        Case Is = 2:    nNumber = Bin2Dec(sNumber)
        Case Is = 8:    nNumber = Val("&O" & sNumber)
        Case Is = 10:   nNumber = Val(sNumber)
        Case Is = 16:   nNumber = Val("&H" & sNumber)
    End Select
    Select Case nFromBase
        Case Is = 2:    CBase = Dec2Bin(nNumber)
        Case Is = 8:    CBase = CStr(Oct(nNumber))
        Case Is = 10:   CBase = CStr(nNumber)
        Case Is = 16:   CBase = CStr(Hex(nNumber))
    End Select
End Function

Thanks I will try it not that I have any doubt that it will work once I know what I'm doing.

Thanks again