Require User Login

I worked out most my problems, now Im trying to work out this Excel problem :D
I have a login macro, where I have setup User initials on sheet7 and using a prompt the user enters there intials.
From here I want to prevent the use of the workbook (Hiding buttons, I already have that working) for non-approved users.

Private Sub CommandButton1_Click()
'All login approved Users are on Hidden sheet "Misc data"
    Dim sLogin As String
    Dim sLogin2 As String
    Dim sht7CellG
    Dim sh7RangeG
    Dim sh7LastRowG

    sLogin = ""
    sLogin = InputBox("Enter initials here! (CAPS only)")
        
    With Sheets("Misc data")
        'Loop thru Column F
        sh7LastRowG = .Cells(Rows.Count, "G").End(xlUp).Row
        Set sh7RangeG = .Range("G1:G" & sh7LastRowG)
    End With

    For Each sh7cellG In sh7RangeG
        Do While sLogin <> sLogin    ' ""   'Prevent user from logging on when input box is blank
            MsgBox "You must enter your Intitals, initials must be approved! (Caps only!)"
            sLogin = InputBox("Enter Initials here (Caps only!)")
        Loop
        If sh7cellG.Value = sLogin Then 'only allow users who are listed on sheet7
            'MsgBox sh7cellG.Offset(0, 1).Value  'for testing
            sLogin2 = sh7cellG.Offset(0, 1).Value
            Call Button_Controls.Buttons_Enabled
        End If
    Next sh7cellG

    Sheets(1).Shapes.Range(Array("CommandButton1")).Visible = False

    Sheets("Main Page").Unprotect
    Sheets("Main Page").Range("E16").Value = sLogin2 & " " & Now()
    Sheets("Main Page").Protect
    sLogin = sLogin & " " & Now

    'Begin Registry setting
    '"appname:=" = Desired name you create, variable or string, preferred a string
    '"section:=" = Desired name you create, variable or string
    '"Key:=" = Desired name you create, variable or string
    'setting:=" = variable or string
    SaveSetting appname:="DTI Val_CAl Log", section:="User", _
                Key:="Login", setting:=sLogin
    'End registry setting
End Sub

Attached file has internal macros.

Any hints, tips or examples are appreciated.

Not really sure by your post what you want done? Everything seems alright in your workbook. As for non-approved users, maybe you should try hiding all sheets except fo rthe Main Page sheet and if the user initials match up, unhide appropriate sheets, else keep them hidden.

All the sheets are normally hidden, they are viewable for this query.
The current code doesnt work, I can type anything at it allows the buttons to be enable on my form.

Here is one way.

Private Sub CommandButton1_Click()
    Dim sLogin As String
    Dim sLogin2 As String
    Dim blnValidLogin As Boolean
    
    Dim rngLoginInfo As Range
    
    Set rngLoginInfo = Intersect(Sheets("Misc Data").Range("G1").CurrentRegion, _
                                 Sheets("Misc Data").Range("G:H"))
    
    Do
        sLogin = UCase(InputBox("Enter initials here! (CAPS only)"))
        If Len(sLogin) > 0 Then
            vntMatch = Application.Match(sLogin, rngLoginInfo.Columns(1), 0)
            If IsError(vntMatch) Then
                ' invalid password
                sLogin = ""
                blnValidLogin = False
            Else
                sLogin2 = rngLoginInfo.Cells(vntMatch, 2)
                blnValidLogin = True
            End If
        Else
            ' Deal with Cancel or loop again
            blnValidLogin = False
            If MsgBox("Do you wish to continue", vbYesNo) = vbNo Then
                sLogin = "Cancel"
            Else
                sLogin = ""
            End If
        End If
    Loop While Len(sLogin) = 0
    
    If blnValidLogin Then
        Call Button_Controls.Buttons_Enabled
    Else
        Exit Sub
    End If

    Sheets(1).Shapes.Range(Array("CommandButton1")).Visible = False

    Sheets("Main Page").Unprotect
    Sheets("Main Page").Range("E16").Value = sLogin2 & " " & Now()
    Sheets("Main Page").Protect
    sLogin = sLogin & " " & Now

    'Begin Registry setting
    '"appname:=" = Desired name you create, variable or string, preferred a string
    '"section:=" = Desired name you create, variable or string
    '"Key:=" = Desired name you create, variable or string
    'setting:=" = variable or string
    SaveSetting appname:="DTI Val_CAl Log", section:="User", _
                Key:="Login", setting:=sLogin
    'End registry setting
End Sub

It uses the MATCH function to check whether the initials are in column G.
There is also a prompt incase the user wants to escape the process of trying intials entry.

Thank you Andy!
Im going to have to study this one, I understand some of it.