ignore blank cell value copy value to other column

[farrukh]

Hi All,

I have a data in column some cells are blank some are fill . i need that the the values are copy and paste in other column in a sequence without blank cell.The workbook is attached with.



Regards,
hammeed

[arlu1201]

Use this code

Option Explicit

Sub data()
Dim lrow As Long, i As Long

With Worksheets("Sheet1")
    lrow = .Range("H" & .Rows.Count).End(xlUp).Row
    For i = 3 To lrow
        If .Range("H" & i).Value <> "" Then
            .Range("A" & .Rows.Count).End(xlUp).Offset(1, 0).Value = .Range("H" & i).Value
        End If
    Next i
End With
End Sub

Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Hold the Alt key, and press the F11 key, to open the Visual Basic Editor
Choose Insert | Module
Where the cursor is flashing, choose Edit | Paste

To run the Excel VBA code:
Choose Tools | Macro | Macros
Select a macro in the list, and click the Run button.

[Steffen Thomsen]

Try this.

Sub steffen()

Dim x As Integer
Dim uRow As Integer

x = 3
uRow = Sheets(1).Range("H60000").End(xlUp).Row

For i = 3 To uRow
    If Not Cells(i, 8) = "" Then
        Cells(x, 1) = Cells(i, 8)
        x = x + 1
    End If
Next i

End Sub

If it's ok just to delete the blanks, then use this:

Sub steffen2()

With Sheets(2).Range("H3:H" & Range("H6000").End(xlUp).Row)
    On Error Resume Next
    Do
        .Find("", , xlValues, xlWhole, xlNext).EntireRow.Delete
    Loop Until Err.Number > 0
End With

End Sub

[nilem]

or

Sub data2()
Range("H3", Cells(Rows.Count, "H").End(xlUp)).SpecialCells(2).Copy Range("A3")
End Sub

[farrukh]

arlu1201,stephen,nelam


Thank you very much all the solution works for me.


Bundle of thanks

hammeed