How to add the columns data of several xlsx files of a folder in another xlsx file

You mean you want to consolidate the data of all the files into one separate workbook?

Try this code

Option Explicit

Sub cons_data()

Dim Master As Workbook
Dim sourceBook As Workbook
Dim sourceData As Worksheet
Dim CurrentFileName As String
Dim myPath As String

'The folder containing the files to be recap'd
myPath = "D:\Test"

'Finds the name of the first file of type .xls in the current directory
CurrentFileName = Dir(myPath & "\*.xlsx")

'Create a workbook for the recap report
Set Master = ThisWorkbook

With Master.Worksheets("Sheet1")
    .Range("A1").Value = "ID"
    .Range("B1").Value = "Category"
    .Range("C1").Value = "Name"
End With

Do
    Workbooks.Open (myPath & "\" & CurrentFileName)
    Set sourceBook = Workbooks(CurrentFileName)
    Set sourceData = sourceBook.Worksheets("Sheet1")
    
        With sourceData
            .Range("A2:C" & Range("C" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets("Sheet1").Range("A" & Master.Worksheets(1).Rows.Count).End(xlUp).Offset(1, 0)
        End With
       
    sourceBook.Close
  
'Calling DIR w/o argument finds the next .xlsx file within the current directory.
CurrentFileName = Dir()
Loop While CurrentFileName <> ""

End Sub

Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Hold the Alt key, and press the F11 key, to open the Visual Basic Editor
Choose Insert | Module
Where the cursor is flashing, choose Edit | Paste

To run the Excel VBA code:
Choose Tools | Macro | Macros
Select a macro in the list, and click the Run button.

Made a few changes.

Option Explicit

Sub cons_data()

Dim Master As Workbook
Dim sourceBook As Workbook
Dim sourceData As Worksheet
Dim CurrentFileName As String
Dim myPath As String

Application.ScreenUpdating = False

'The folder containing the files to be recap'd
myPath = "D:\Test"

'Finds the name of the first file of type .xls in the current directory
CurrentFileName = Dir(myPath & "\*.xlsx")

'Create a workbook for the recap report
Set Master = ThisWorkbook

With Master.Worksheets("Sheet1")
    .Range("A1").Value = "ID"
    .Range("B1").Value = "Category"
    .Range("C1").Value = "Name"
End With

Do
    Workbooks.Open (myPath & "\" & CurrentFileName)
    Set sourceBook = Workbooks(CurrentFileName)
    Set sourceData = sourceBook.Worksheets("Sheet1")
    
        With sourceData
            .Range("B2:C" & Range("C" & .Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets("Sheet1").Range("B" & Master.Worksheets(1).Rows.Count).End(xlUp).Offset(1, 0)
        End With
       
    sourceBook.Close
  
'Calling DIR w/o argument finds the next .xlsx file within the current directory.
CurrentFileName = Dir()
Loop While CurrentFileName <> ""

With Master.Worksheets("Sheet1")
    .Range("A2:A" & Range("B" & .Rows.Count).End(xlUp).Row).ClearContents
    .Range("A2:A" & Range("B" & .Rows.Count).End(xlUp).Row).FormulaR1C1 = "=row()-1"
    .Range("A2:A" & Range("B" & .Rows.Count).End(xlUp).Row).Value = .Range("A2:A" & Range("B" & .Rows.Count).End(xlUp).Row).Value
End With

Application.ScreenUpdating = True

End Sub

Are your headers not in row1 in the final output file? In that case, your change from -1 to-3 is fine.

Change this code

 With Master.Worksheets("Sheet1")
    .Range("A1").Value = "ID"
    .Range("B1").Value = "Category"
    .Range("C1").Value = "Name"
End With

to this

With Master.Worksheets("Sheet1")
    .cells.clearcontents
    .Range("A1").Value = "ID"
    .Range("B1").Value = "Category"
    .Range("C1").Value = "Name"
End With