Fill blank cells in column with value above

Dear Expert,
I was learnt to to autofill of the cells with value above.
But when I found the Fonts changed, it did not work.
Can you tell me how to fine-tune and make it work all the time either for text or numbers?
Thanks
Elton

Sub FillColBlanks()
'fill blank cells in column with value above
Dim wks As Worksheet
Dim rng As Range
Dim LastRow As Long
Dim col As Long

Set wks = ActiveSheet
With wks
   col = ActiveCell.Column
   'or
   'col = .range("b1").column

   Set rng = .UsedRange  'try to reset the lastcell
   LastRow = .Cells.SpecialCells(xlCellTypeLastCell).Row
   Set rng = Nothing
   On Error Resume Next
   Set rng = .Range(.Cells(2, col), .Cells(LastRow, col)) _
                  .Cells.SpecialCells(xlCellTypeBlanks)
   On Error GoTo 0

   If rng Is Nothing Then
      
       Exit Sub
   Else
       rng.FormulaR1C1 = "=R[-1]C"
   End If

   'replace formulas with values
   With .Cells(1, col).EntireColumn
       .Value = .Value
   End With

End With

End Sub

Do you want to copy the fonts and format or not?

Sub FillColBlanks_Copy_Values_Only()

    On Error Resume Next
    With ActiveCell.EntireColumn.SpecialCells(xlCellTypeBlanks)
        .FormulaR1C1 = "=R[-1]C"
        .Value = .Value
    End With

End Sub

Sub FillColBlanks_Copy_ValuesAndFormatting()

    Dim a As Range
    Application.ScreenUpdating = False
    On Error Resume Next
    With ActiveCell.EntireColumn.SpecialCells(xlCellTypeBlanks)
        For Each a In .Areas
            a.Offset(-1).Resize(1).Copy
            a.PasteSpecial xlPasteFormats
            a.PasteSpecial xlPasteValues
        Next a
    End With
    Application.CutCopyMode = False
    Application.ScreenUpdating = True

End Sub