Split data in to multiple tabs using value in column

[Manpar]

Hello all,

I have a data set in the worksheet "Master" with total of 6 columns at the more than 500 thousand rows. I want your help in splitting this data in to multiple tabs based on the values in column 4. I'm looking at the end result in this way, I have multiple tabs named by the value in column 4 and all the data points (6 columns) related to the name of the tab.

[Bob Phillips]

Try this

Sub SplitData()
Dim sh As Worksheet
Dim lastCode As String
Dim lastrow As Long
Dim startrow As Long
Dim i As Long

    With ActiveSheet
    
        lastrow = .Cells(.Rows.Count, "A").End(xlUp).Row
        .Range("A1").Resize(lastrow, 6).Sort key1:=.Range("D1"), order1:=xlAscending, Header:=xlYes
        For i = 2 To lastrow
        
            If .Cells(i, "A").Value <> lastCode Then
            
                lastCode = .Cells(i, "D").Value
                Set sh = .Parent.Worksheets.Add(after:=.Parent.Worksheets(.Parent.Worksheets.Count))
                sh.Name = lastCode
                startrow = i
                Do While .Cells(i, "D").Value = lastCode
                
                    i = i + 1
                Loop
                
                .Rows(1).Copy sh.Range("A1")
                .Rows(startrow).Resize(i - startrow).Copy sh.Range("A2")
                
                i = i - 1
            End If
        Next i
    End With
End Sub

[Manpar]

Fantastic!! This works