Macro to search & replace then copy to another column on the same row?

Hi,

I have 3 columns D,E,and F

D will have a list of manufacture names, E will have category Names, and F will have a description of the products.

Example:

D=FOXCONN, GIGABYTE, INTEL
E=MOTHERBOARD
F=GA/1366/I7/X58/3XF/SATA3/USB3

What i am trying to do is search for a specific data value on F description when data value is found replace that value with a value i choose but copy it to E Column after the Category Name on the same row. But it can only search within a particular manufacture and Category which is on column D and E.

Example:

Only search if Manufacture Gigabyte on column d, with the Category Name Motherboard on column e is present. If there present then search and find I7 on column F (match) and then I7 will be replaced with name of choosing which is |Core I7 and joined after Column E MOTHERBOARD

Example Finished:

E=MOTHERBOARD|CORE I7

I have been working on this for awhile and searched everywhere to see if there was example of what i am trying to accomplish. I don't have much experience with VB Macros so your help would be appreciated.

Anybody have any ideas of how to do this. Or do you need more clarification on what i am trying to do?

thanks

Perhaps you could upload your worksheet (or a mockup of your worksheet).

Backup your data!
I don't think I fully understood what you need.
Run this macro, and tell me how I can make it better.
Between running the macro, and reading my comments in the code,
perhaps you can better explain what you need.

Sub SearchFor1155()
    Dim rgF As Range, rgCell As Range, sAddress
    
    'Search Column F
    Set rgF = Range("F1:F" & Cells(Rows.Count, "F").End(xlUp).Row)
    With rgF
        'Search for "/1155/"
        Set rgCell = .Find(What:="/1155/", LookIn:=xlValues)
        If Not rgCell Is Nothing Then
            sAddress = rgCell.Address
            Do
                'If "MOTHERBOARD" is in Column E
                '& If "FOXCONN" is in Column D
                If rgCell(1, 0) = "MOTHERBOARD" _
                And rgCell(1, -1) = "FOXCONN" Then
                    'Then Place "MOTHERBOARD|1155 Socket" in Column K
                    rgCell(1, 6) = "MOTHERBOARD|1155 Socket"
                End If
                'Find next "/1155/"
                Set rgCell = .FindNext(rgCell)
            Loop While Not rgCell Is Nothing And rgCell.Address <> sAddress
        End If
    End With
End Sub

yes, its almost exactly what i need. Instead of putting the results on column k, i need the results to be on column e?

thanks

Sub SearchFor1155()
    Dim rgF As Range, rgCell As Range, sAddress
    
    'Search Column F
    Set rgF = Range("F1:F" & Cells(Rows.Count, "F").End(xlUp).Row)
    With rgF
        'Search for "/1155/"
        Set rgCell = .Find(What:="/1155/", LookIn:=xlValues)
        If Not rgCell Is Nothing Then
            sAddress = rgCell.Address
            Do
                'If "MOTHERBOARD" is in Column E
                '& If "FOXCONN" is in Column D
                If rgCell(1, 0) = "MOTHERBOARD" _
                And rgCell(1, -1) = "FOXCONN" Then
                    'Then Place "MOTHERBOARD|1155 Socket" in Column E
                    rgCell(1, 0) = "MOTHERBOARD|1155 Socket"
                End If
                'Find next "/1155/"
                Set rgCell = .FindNext(rgCell)
            Loop While Not rgCell Is Nothing And rgCell.Address <> sAddress
        End If
    End With
End Sub

thats it, thanks