I have 14,900 Lines of code in my Sub, Could someone show me how to be more efficient?

(1) Never used "As Integer" change to "As Long"
Reason: Computers today find long (integers) easier to use than (short) integers.
"As Integer" creates a short integer.
"As Long" creates a long integer.

(2)

Range("b5").Select
actual_new(0) = Range("b5").Value

There is no reason to "Select" a cell before putting a value from a cell into an array, or before putting a value from an array into a cell.
That will almost cut your code in half.

(3)

x = 0
Do Until x = 8
monthly_new(x) = monthly_new(x) + actual_new(x)
monthly_mbbtab(x) = monthly_mbbtab(x) + actual_mbbtab(x)
monthly_hpc(x) = monthly_hpc(x) + actual_hpc(x)
monthly_upgrade(x) = monthly_upgrade(x) + actual_upgrade(x)
monthly_gwg(x) = monthly_gwg(x) + actual_gwg(x)
monthly_gross(x) = monthly_gross(x) + actual_gross(x)
x = x + 1
Loop

Should be:

For x = 0 to 7
    monthly_new(x) = monthly_new(x) + actual_new(x)
    monthly_mbbtab(x) = monthly_mbbtab(x) + actual_mbbtab(x)
    monthly_hpc(x) = monthly_hpc(x) + actual_hpc(x)
    monthly_upgrade(x) = monthly_upgrade(x) + actual_upgrade(x)
    monthly_gwg(x) = monthly_gwg(x) + actual_gwg(x)
    monthly_gross(x) = monthly_gross(x) + actual_gross(x)
Next x

(4) I'm not going to copy your code, but I've copied the comments.
I then added the cells for each group. These cells are five rows apart.
And so:

Dim i As Long
'
'
'...
'(0) BARNEGAT   = N5:S5
'(1) BRIDGETON  = N10:S10
'(2) GALLOWAY   = N15:S15
'(3) HAMMONTON  = N20:S20
'(4) MANTUA     = N25:S25
'(5) MILLVILLE  = N30:S30
'(6) VENTNOR    = N35:S35
'(7) VINELAND   = N40:S40

For i = 0 To 7
    Range("N" & (5 + i * 5)) = monthly_new(i)
    Range("O" & (5 + i * 5)) = monthly_mbbtab(i)
    Range("P" & (5 + i * 5)) = monthly_hpc(i)
    Range("Q" & (5 + i * 5)) = monthly_upgrade(i)
    Range("R" & (5 + i * 5)) = monthly_gwg(i)
    Range("S" & (5 + i * 5)) = monthly_gross(i)
Next i

Multiplication takes precedence over addition, so 5 + i * 5 is the same as 5 + (i * 5).
"N" & (5 + i * 5) when i = 0 creates a string "N5"
"N" & (5 + i * 5) when i = 7 creates a string "N40"

I am not asking for some fish.
I am looking for some one to teach me how to fish here.

(5) You can loop through your Worksheets 2 through 9 with the following code:

Dim wb As Workbook, i As Long
'
'
'...
'    
Set wb = ThisWorkbook
For i = 2 To 9
    With wb.Worksheets(i)
        ' Do something here
    End With
Next i

Between the with & end with you can refer to a Range like so:
.Range("A1") = whatever or whatever = .Range("A1")

The dot before Range means connect with: wb.Worksheets(i)

For example:

Sheet2.Range("z154").Value = Barnegat_Needed_New_Goal  'Range("z4").Value
Sheet3.Range("z154").Value = Bridgeton_Needed_New_Goal  ' Range("z9").Value
Sheet4.Range("z154").Value = Galloway_Needed_New_Goal   ' Range("z14").Value
Sheet5.Range("z154").Value = Hammonton_Needed_New_Goal  ' Range("z19").Value
Sheet6.Range("z154").Value = Mantua_Needed_New_Goal     ' I didn't look up the rest,  
Sheet7.Range("z154").Value = Millville_Needed_New_Goal  ' but if they are five rows apart
Sheet8.Range("z154").Value = Ventnor_Needed_New_Goal    ' then ...
Sheet9.Range("z154").Value = Vineland_Needed_New_Goal

The loop would take care of the left side of equals.

.Range("Z154").Value =

The right side of the equals might be:

Range("Z" & 4 + (i - 2) * 5).Value

"Z" & 4 + (i - 2) * 5 when i = 2 is a string "Z4"
"Z" & 4 + (i - 2) * 5 when i = 3 is a string "Z9"
etc.
Note: Range without a dot refers to the Active Worksheet.

As an afterthought,

Dim wb As Workbook, i As Long
'
'
'...
'    
Set wb = ThisWorkbook
For i = 2 To 9
    With wb.Worksheets(i)
        ' Do something here
    End With
Next i

Can be simplified to:

Dim i As Long
'
'
'...
'    
For i = 2 To 9
    With Worksheets(i)
        ' Do something here
    End With
Next i

Does this do the same thing as your code?

Sub UpdateForm()
    Dim n As Long
    
    'Barnegat = 0
    'Bridgeton = 1
    'Galloway = 2
    'Hamonton = 3
    'Mantua = 4
    'Millville = 5
    'Ventnor = 6
    'Vineland = 7
    
    For n = 0 To 7
        Cells((n + 1) * 5, "N") = Cells((n + 1) * 5, "N") + Cells((n + 1) * 5, "B")
        Cells((n + 1) * 5, "O") = Cells((n + 1) * 5, "O") + Cells((n + 1) * 5, "C")
        Cells((n + 1) * 5, "P") = Cells((n + 1) * 5, "P") + Cells((n + 1) * 5, "D")
        Cells((n + 1) * 5, "Q") = Cells((n + 1) * 5, "Q") + Cells((n + 1) * 5, "E")
        Cells((n + 1) * 5, "R") = Cells((n + 1) * 5, "R") + Cells((n + 1) * 5, "F")
        Cells((n + 1) * 5, "S") = Cells((n + 1) * 5, "S") + Cells((n + 1) * 5, "G")
    Next
End Sub

Or ...

    For i = 5 To 40 Step 5
        Rows(i).Range("B1:G1").Copy
        Rows(i).Range("N1:S1").PasteSpecial Paste:=xlPasteValue, _
                                            Operation:=xlPasteSpecialOperationAdd
    Next i