Can a Command Button's position be kept moving along the TargetCell ROW in the same Column

you could use a code like this, but you will need to adjust the numbers to make it match your row heights

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
ActiveSheet.Shapes("Button 1").Top = 15 * Target.Row - 15
End Sub

Try This,
It goes in the worksheet module

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Column <> 2 Then
        CommandButton1.Visible = False
        Exit Sub
    End If
    Dim ScRow As Long
    Dim ScCol As Integer
    ScRow = ActiveCell.Row
    ScCol = ActiveCell.Column

    With ActiveSheet.Shapes("CommandButton1")
        .Visible = True
        .Top = Cells(ScRow, ScCol).Top
        .Left = Cells(ScRow, ScCol + 1).Left
    End With

End Sub

The Avatar originally had no hat, until Teylyn gave it one for Christmas a few years ago.

I am not entirely sure what you are asking.
If you make a UserForm with two buttons, then in the button that becomes visible would have the code
userform1.show

You can use this code to show the command button when column B is selected

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Column <> 2 Then Exit Sub

    With UserForm1
        .StartUpPosition = 0
        .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
        .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
        .Show
    End With

End Sub

For your first Command button you do not indicate what last row you are referring to so I will assume it is the 1st empty row in Sheet2 Column A.

Private Sub CommandButton1_Click()
    Dim Sh1 As Worksheet, Sht2 As Worksheet, Rws As Long
    Set sht1 = Worksheets(1)
    Set Sht2 = Worksheets(2)
    Rws = Sht2.Cells(Rows.Count, "A").End(xlUp).Row + 1
    Application.ScreenUpdating = 0
    ActiveCell.Range("A1:B1,D1:F1").Copy
    Sht2.Cells(Rws, 1).PasteSpecial Paste:=xlPasteValues
    Application.CutCopyMode = 0
    UserForm1.Hide

End Sub

From this you should be able to get your other codes to work.

Dear Dave,

Thanks for the help again and I am sorry that I was not clear enough but I require the contents to be copied in the same sheet in the last unfilled row as you mentioned..
So in the present sheet If I clicked on any of the two buttons

Renew FD - The aforesaid contents should get copy-pasted in the 11th Row , if the seelected cell is B2 then the contents in the cell A2,B2,E2,F2,G2 will get copied to the same set of cells i.e cell A11 ,B11,E11,F11,G11 and the contents in the cells cell I2 to cell cell H11 and in the cell I11 will be the same difference of days as it is between the opening date and the Maturity date in the Target cell.
The original Maturity Amount in the cell K2 now should go in the cell D11 as it now becomes the Amount ..

Continue FD - Everything same except that the Maturity Date should be blank..

One very important thing I realised is that the user from should only be visible till the rows the data is filled and not in the blank rows and the user form has the Renew FD enabled by default can this be normal?

Please also help me for the delete last entry from the same sheet and the delete range as mentioned earlier that is if im on the 8th row and there are 10rwos filled then all the three rwos beginning from 8 below 9 and 10 get deleted..

Thanks in advance...

Warm Regards
e4exce

You can count the cells first before showing the userform

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Column <> 2 Then Exit Sub
    If WorksheetFunction.CountA(Target.Offset(0, -1).Range("A1:L1")) < 10 Then Exit Sub
    
    With UserForm1
        .StartUpPosition = 0
        .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
        .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
        .Show
    End With

End Sub

Replace the code in the command button1 with this

Private Sub CommandButton1_Click()
    Dim Rws As Long
    Rws = Cells(Rows.Count, "B").End(xlUp).Row + 1
    
    ActiveCell.Range("A1:B1").Copy Destination:=Cells(Rws, 2)
    ActiveCell.Range("D1:F1").Copy Destination:=Cells(Rws, 5)
    UserForm1.Hide

End Sub

Show us your attempts for the other questions.

Show us your attempts for the other questions.

Dear Dave,

I have made a few changes in the code you provided as well as added some new code for the command buttons, please advise if thats correct though its working..

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Column <> 2 Or Target.Row = 1 Then Exit Sub
    If WorksheetFunction.CountA(Target.Offset(0, -1).Range("A1:L1")) < 10 Then Exit Sub
    
    With UserForm1
        .StartUpPosition = 0
        .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
        .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
        .Show
    End With

End Sub

I also wanted to know about a strange thing that when I tried using the column names as it is it gave an incorrect answer..
I mean I had to use one column behind to refer the actual column.. in the code for the first button..

Now there's a slight problem as the copied values are getting copied with formulas and that creates a circulr reference so how do I amend that as the Maturity amount of the original active row becomes the Amount in the Renewed or COntinued FD..

Can you please make the existing formulas in the columns A, col K and Col L as values after using the formula as I want these formulas to also appear when the REnewed FD and Continue FD is in progress..lets say I have dragged the formulas till the row 11 that is for 10 records and then I add a FD by Renew FD then I need the formula in the column A to show the Sr. No as well as the col K to show the Maturity Amount and the col L the interest..

I dont know how to write these formulas in this button click event..


Please find my codes:

Private Sub CommandButton1_Click()
    Dim Rws As Long
    Rws = Cells(Rows.Count, "B").End(xlUp).Row + 1
    
    ActiveCell.Range("A1:B1").Copy Destination:=Cells(Rws, 2)
    ActiveCell.Range("J1").Copy Destination:=Cells(Rws, 4)
    ActiveCell.Range("D1:F1").Copy Destination:=Cells(Rws, 5)
    ActiveCell.Range("H1").Copy Destination:=Cells(Rws, 8)
    Cells(Rws, 9).Value = Application.WorksheetFunction.Text(Cells(Rws, 8).Value + DateDiff("d", ActiveCell.Range("G1"), ActiveCell.Range("H1")), "dd-mmmm-yy")
    UserForm1.Hide

End Sub

Private Sub CommandButton2_Click()
    Dim Rws As Long
    Rws = Cells(Rows.Count, "B").End(xlUp).Row + 1
    
    ActiveCell.Range("A1:B1").Copy Destination:=Cells(Rws, 2)
    ActiveCell.Range("J1").Copy Destination:=Cells(Rws, 4)
    ActiveCell.Range("D1:F1").Copy Destination:=Cells(Rws, 5)
    ActiveCell.Range("H1").Copy Destination:=Cells(Rws, 8)
    UserForm1.Hide
End Sub

Private Sub CommandButton3_Click()

Dim lastrow As Long
lastrow = ActiveSheet.UsedRange.Rows.Count

    Range("A" & lastrow, "A" & lastrow).EntireRow.Delete
    
End Sub

Private Sub CommandButton4_Click()
Dim activerow As Long
Dim lastrow As Long

activerow = ActiveCell.Row
lastrow = ActiveSheet.UsedRange.Rows.Count

    Range("B" & activerow, "B" & lastrow).EntireRow.Delete
    
End Sub

Why are you bumping? you said it works.

Please mark this thread as solved as the original question has been answerd.

Then start a new thread.