Can one use a Listbox on UserForm without allowing the user to select an item?

Is there a property which one can set on a listbox (on a userform) which would allow one to display items without allowing the user to select one of the items?

Steven Craig Miller

My first thought is to just have nothing happen in your code when the listbox is being viewed and a value is selected. You can leave the a list box filled but without programmatic meaning. Just create the list box, fill it, and leave it. Is this what you mean?

Hi StevenM
In the ListBox Properties play with the Enabled and the Locked Properties until you get the effect you want.

Hi Steven
Not sure what you're trying to do but try this (change the ListBox name as appropriate)

Private Sub ListBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    Dim i As Long
    For i = 0 To UserForm1.ListBox1.ListCount - 1
        If UserForm1.ListBox1.Selected(i) = True Then
            UserForm1.ListBox1.Selected(i) = False
        End If
    Next i
End Sub

Instead of listing the items in a list box, you could put a linefeed delimited string in a TextBox with Multiline = True, Locked=True and ScrollBars = fmScrollBarsVertical

Try code like this

Private Sub UserForm_Initialize()
    Dim oneCell As Range
    With tbxDisplay
        .MultiLine = True: Rem can be set at design time
        .ScrollBars = fmScrollBarsVertical: Rem design time
        .EnterFieldBehavior = fmEnterFieldBehaviorRecallSelection: Rem design
        
        Rem fill the textbox, crude approach
        For Each oneCell In Range("A1:A25")
            tbxDisplay.Text = tbxDisplay.Text & vbCr & CStr(oneCell.Value)
        Next oneCell
        
        .SelStart = 0: Rem run-time only
        .SelLength = 0: Rem run-time only
        .Locked = True: Rem run-time only
        .SetFocus
    End With
    
    
    SomeOtherControl.SetFocus
End Sub

Note that some of the properties specified in the Intialize event could be set at design time rather than in the I. event. Others cannot.
The way to get the scroll bar to appear is to set the focus to the tbxDisplay and then to someOtherControl.

The selection icon cannot be removed. This code puts it out of the way (at the start of the text) but leaves it there. As I was fiddling, I discovered that (as a potential user) the ability to highlight, by selection, part of the contents of the Text Box was a good thing. If your users would feel differently, then KeyDown or MouseUp events could be added to keep the focus away from the text box.

Perhaps

Private Sub TextBox1_Enter()
    TextBox1.SelStart = 0
End Sub

Private Sub TextBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As Single, ByVal y As Single)
    TextBox1.SelStart = 0
End Sub

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Select Case KeyCode
        Case vbKeyTab, vbKeyReturn
        Case Else
            KeyCode = 0
    End Select
End Sub