Simple True/False Colouring (Not Conditional)

I'm looking for a slightly better way of doing the following...

Sub FalseTrueTest2()

    Dim cl As Range
    For Each cl In Range("A2:A" & Range("A" & Rows.Count).End(xlUp).Row)
        Select Case cl.Value
            Case Is = "True"
                cl.Style = "Good"
            Case Is = "False"
                cl.Style = "Bad"
        End Select
    Next
    
End Sub

Hyflex,

I would recommend conditional formatting instead of VBA. highlight column A and create two conditional format formulas:
For the Good style, use this formula: =AND($A1<>"",$A1="True")
For the Bad style, use this formula: =AND($A1<>"",$A1="False")

I do see in your thread title that it says "(Not Conditional)". If it has to be VBA, I'd recommend using autofilter for this operation:

Sub FalseTrueTest2()
    
    On Error Resume Next
    Application.ScreenUpdating = False
    
    With Range("A1", Cells(Rows.Count, "A").End(xlUp))
        .AutoFilter 1, "True"
        .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Style = "Good"
        
        .AutoFilter 1, "False"
        .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Style = "Bad"
        
        .AutoFilter
    End With
    
    Application.ScreenUpdating = True
    
End Sub