Collate data

I need data related to the name in (F10).
Required data is
Queue Name: Which is in C11
Total Assigned : K13
Total Handled time : AS13
The same way for all the names.
Please help me with a macro to do the same thing for 20sheets minimum and I need to pull the data for all the names which are in range (F2:F40) in all the sheets and the corresponding data of Queue name, Total Assigned and Total handled time also.
There is a problem which I found is, for the last name in sheet1 (F40) the corresponding data is in sheet2. Like the same way it may be in other sheets also.
Please help me.
I need all the data in all the sheets in a single sheet. (Note: I cannot unmerge the columns)
Attaching the required file for testing.
====
I have a script which will copy only the required columns to another sheet.

Sub OneCell()
    Sheets("Sheet2").Range("A1:A56").Value = Sheets("Sheet1").Range("C1:C56").Value
    Sheets("Sheet2").Range("B1:B56").Value = Sheets("Sheet1").Range("F1:F56").Value
    Sheets("Sheet2").Range("C1:C56").Value = Sheets("Sheet1").Range("K1:K56").Value
    Sheets("Sheet2").Range("D1:D56").Value = Sheets("Sheet1").Range("AS1:AS56").Value
End Sub

Please help me from this place or at least suggest me something. Give me an idea or a workaround. As I said I need the data as
For a Name: The Queue name is (something), total assigned is (something) and the total handled time is (something) in a single row so that I can get the required output for all the sheets.
At the same time please also help me with copy data in the same way from remaining sheets to the same sheet. (I mean if I want to copy data from another sheet(Sheet3) to sheet2 also then it should not delete the old data in sheet2. It should paste the data in sheet2 from the place where the data ends in sheet2. (Example: if data exists till A42 then if i copy the data from sheet3 to sheet2 then it should start pasting the data from A32. The same way for 20sheets ( sheet3,4,5,.....20).

Here's a start... This code will collect the data from Sheet1 and copy it to Sheet 2.

Sub Gather_Data()
    Dim vD          As Variant
    Dim x           As Long
    Dim y           As Long
    Dim z           As Long

    'COLLECT DATA
    With Worksheets("Sheet1")
        vD = Intersect(.Columns("F:F"), .UsedRange)
        ReDim Preserve vD(1 To UBound(vD), 1 To 4)

        For x = 1 To UBound(vD)
            If Not IsEmpty(vD(x, 1)) Then
                vD(x, 2) = .Cells(x + 1, 3)
                If .Cells(x + 3, 3) = "Total" Then
                    vD(x, 3) = .Cells(x + 3, 11)
                    vD(x, 4) = .Cells(x + 3, 45)
                Else
                    vD(x, 3) = .Cells(x + 1, 10)
                    vD(x, 4) = .Cells(x + 1, 45)
                End If
            End If
        Next x
    End With

    'POST DATA
    With Worksheets("Sheet2")
        z = .Cells(.Cells.Rows.Count, 1).End(xlUp).Row + 1
        For x = 1 To UBound(vD)
            If Not IsEmpty(vD(x, 1)) Then
                For y = 1 To 4
                    .Cells(z, y) = vD(x, y)
                Next y
                z = z + 1
            End If
        Next x
    End With
End Sub

HTH,
-Rich

Oh my god. You are really great. Thank you very much. You really did it. Thanks a lot.
Just one more help. If I have the data like the same in 3 sheets. Can you help me in gathering all the sheets data the same way to a single sheet.
Please find the attachment. The data in single sheet should also be in the same format and actually from the sheet 2 and and sheet3 the data is in different columns and rows.
I mean the data in sheet1 is in different rows as you have already provided me the solution but for sheets2 and sheets3 the data is in different rows and columns. So, I need to collate all the data to a single sheet in your given format.
In the given sheet under the name you will find two queue names. I need that information also to be in the data.

Sorry for the delay... Try this code

Sub Sheets321()
    Dim x           As Long
    Dim y           As Long
    Dim z           As Long
    Dim lRow        As Long
    Dim vD          As Variant
    Dim vR          As Variant
    Dim rRow        As Range

    'COLLECT DATA
    With Worksheets.Add(Sheets(1))
        .Name = "One"
        For x = 1 To Worksheets.Count
            If Worksheets(x).Name <> "One" Then
                lRow = .Cells.SpecialCells(xlCellTypeLastCell).Row + 1
                vD = Worksheets(x).UsedRange.Value2
                .Cells(lRow, 1).Resize(UBound(vD, 1), UBound(vD, 2)) = vD
            End If
        Next x
        .Columns("c:c").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
        .Cells.SpecialCells(xlCellTypeBlanks).Delete (xlShiftToLeft)
        vD = .UsedRange.Value2

        'SEARCH AND COPY DATA
        ReDim vR(1 To UBound(vD), 1 To 4)
        lRow = 0
        For x = 1 To UBound(vD)
            If vD(x, 1) = "User Name:" Then
                y = 0
                Do
                    y = y + 1
                    If y + x > UBound(vD) Then Exit Do
                Loop Until vD(x + y, 1) = "User Name:" Or Len(vD(x + y, 1)) = 0
                For z = 1 To y - 1
                    If vD(x + z, 1) <> "Total" And vD(x + z, 1) <> "Queue" Then
                        lRow = lRow + 1
                        vR(lRow, 1) = vD(x, 2)        'COPY USER NAME
                        vR(lRow, 2) = vD(x + z, 1)        'COPY QUEUE NAME
                        vR(lRow, 3) = Format(vD(x + z, 5), "0")        'COPY TOTAL CHATS
                        vR(lRow, 4) = Format(vD(x + z, 8), "hh:mm:ss")        'COPY TOTAL TIME
                    End If
                Next z
            End If
        Next x

        'POST RESULTS
        .Cells.Delete
        .Cells(1, 1).Resize(UBound(vR, 1), UBound(vR, 2)) = vR
    End With
End Sub

HTH,
Rich