Code does what its suppose to do, how can i make it better

Can't check this so try it on a back up workbook

Option Explicit
Sub CopyFromAnotherWorkbook()

' CopyFromAnotherWorkbook - Copy data from Previous 7 days service disruption.xlsm to MI&SD Tracking.xlsm

Dim LastRowColB As Long 'Count last row in Previous 7 days service disruption.xlsm
Dim FinalRowColA As Long 'Count last row in MI&SD Tracking.xlsm
Dim sPath As String
Dim wbSource As Workbook

sPath = ThisWorkbook.Path & "\"

With Application
.ScreenUpdating = False
 
           Set wbSource = Workbooks.Open(sPath & "Previous 7 days Service Disruptions.xlsm")
With wbSource.Worksheets("Report 1")
        LastRowColB = .Range("b65536").End(xlUp).Row
    'Get Region code and autofill
    .Range("H5").Formula = "=TRIM(LEFT(F5,FIND(""SD"",F5)-1))"
    Range("H5").AutoFill Destination:=.Range("H5:H" & LastRowColB)
    'Copy Data in Previous 7 days service disruption.xlsm
    .Range("B5:K" & LastRowColB).Copy
 End With
 
    With ThisWorkbook.Worksheets("SD Raw Data")
    'Find row to paste new data to end of current data
    FinalRowColA = .Range("A65536").End(xlUp).Row + 1
      .Range("A" & FinalRowColA).PasteSpecial Paste:=xlPasteValues
    End With
.DisplayAlerts = False
   wbSource.Close
.DisplayAlerts = True
.ScreenUpdating = False
End With
End Sub

Made a few changes like removing all selecting of cells and activating of worksheets which is unnecessary along with not needing to use Autofill to populate the cells with formula and also turning screen updating back on which your code didn't do...

Sub CopyFromAnotherWorkbook()

' CopyFromAnotherWorkbook - Copy data from Previous 7 days service disruption.xlsm to MI&SD Tracking.xlsm

    Dim LastRowColB As Long    'Count last row in Previous 7 days service disruption.xlsm
    Dim FinalRowColA As Integer    'Count last row in MI&SD Tracking.xlsm
    Dim Path As String

    Path = ThisWorkbook.Path & "\"
    Application.ScreenUpdating = False
    Application.Workbooks.Open (Path & "Previous 7 days Service Disruptions.xlsm")
    With Workbooks("Previous 7 days Service Disruptions.xlsm").Worksheets("Report 1")
        LastRowColB = .Range("B" & Rows.Count).End(xlUp).Row
        'Get Region code and autofill
        .Range("H5:H" & LastRowColB).Formula = "=TRIM(LEFT(F5,FIND(""SD"",F5)-1))"
        'Copy Data in Previous 7 days service disruption.xlsm
        .Range("B5:K" & LastRowColB).Copy
    End With
    'Paste Data to end of current data
    With Workbooks("MI&SD Tracking.xlsm").Worksheets("SD Raw Data")
        FinalRowColA = .Range("A" & Rows.Count).End(xlUp).Row
        .Range("A" & FinalRowColA + 1).PasteSpecial Paste:=xlPasteValues
    End With
    Workbooks("Previous 7 days Service Disruptions.xlsm").Close False
    Application.ScreenUpdating = True

End Sub

Dom

A With...End With construct enables you to perform multiple operations on an object without repeatedly referring to it which is more efficient and involves less typing

As an example this:

Range("A1").Formula = "=A2+A3"
Range("A1").Copy
Range("A1").PasteSpecial xlPasteValues

Can be written as:

With Range("A1")
    .Formula = "=A2+A3"
    .Copy
    .PasteSpecial xlPasteValues
End With

Dom

This might suffice:

Sub snb()
  with getobject(Thisworkbook.path & "\Previous 7 days Service Disruptions.xlsm")
    sn=.sheets("Report 1").cells(1).currentregion.offset(,1).resize(,10)
    .close false
  end with

  thisworkbook.sheets("SD Raw Data").cells(rows.count,1).end(xlup).offset(1).resize(ubound(sn),ubound(sn,2))=sn
End Sub