Macro to copy/paste info in different sheets and to delete last entry

I think the SETCOUNT thing doesn't work any more, when you DELETE you always want to go from last sheet to first, but when you COPY new data you are now searching from first sheet to last looking for an empty one. So, I think the macros all need to change. Use these instead:

Option Explicit

Sub CopySequential()
Dim w As Long, wsCnt As Long

'find first empty sheet
    For wsCnt = 1 To 50
        If Sheets("Calculations" & wsCnt).Range("E29") = "" Then Exit For
        If wsCnt = 50 Then
            MsgBox "No more empty sheets"
            Exit Sub
        End If
    Next wsCnt
    
'transfer data to found sheet
    With Sheets("Calculations" & wsCnt)
        .Range("E29").Value = Sheets("DataEntry").Range("C22").Value
        .Range("G29").Value = Sheets("DataEntry").Range("E22").Value
        .Range("E33").Value = Sheets("DataEntry").Range("C25").Value
        .Range("G33").Value = Sheets("DataEntry").Range("E25").Value
        .Range("E31").Value = Sheets("DataEntry").Range("G24").Value
    End With

End Sub

Sub DeleteSequential()
Dim wsCnt As Long

    For wsCnt = 50 To 1 Step -1
        If Sheets("Calculations" & wsCnt).Range("E29") <> "" Then Exit For
        If wsCnt = 1 Then
            MsgBox "No data to delete"
            Exit Sub
        End If
    Next wsCnt

    Sheets("Calculations" & wsCnt).Range("E29,G29,E33,G33,E31").Value = ""
    
End Sub

Sub ResetCalcSheets()
Dim wsCnt As Long

    For wsCnt = 1 To 50
        Sheets("Calculations" & wsCnt).Range("E29,G29,E33,G33,E31").Value = ""
    Next wsCnt
    
End Sub