VBA to format bold a concatenated string

Similar to this thread - http://www.excelforum.com/excel-gene...ted-items.html

All I need to do is something similar BUT only one item is to be bold. But that bold item will change in charater length, so counting where to begin the bold (like shown above = 58 character) doesnt work for me. I need to join (3) items where the second itme is the one to be bold and changes.

Problem:
A flat fee of $11,750.00 is agreed upon for the delivery of the services.

This dollar amount changes any where from $1.00 to $999,999.00

Results to be placed in A155.

THANK YOU IN ADVANCE!

Assuming the starting phrase is in A1, the second in A2, and the third in A3,

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("A1,A2,A3")) Is Nothing Then
        On Error GoTo Oops
        Application.EnableEvents = False
        With Me.Range("A155")
            .Value = Trim(Me.Range("A1").Text & " " & _
                          Me.Range("A2").Text & " " & _
                          Me.Range("A3").Text)
            .Characters(Start:=Len(Me.Range("A1").Text) + 2, _
                        Length:=Len(Me.Range("A2").Text)).Font.Bold = True
        End With
Oops:
        Application.EnableEvents = True
    End If
End Sub

Thank you for the quick response and solution

While that solution does indeed work, your assumption is not correct, since I failed to specify that. Sorry! My fault!

The phrases actually exisits on a different worksheet (Titled: "DO NOT DELETE") and on Row 24. Therefore, A24, B24, and C24.

I edited your coded to now be:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("'DO NOT DELETE'!A24,'DO NOT DELETE'!B24,'DO NOT DELETE'!C24")) Is Nothing Then
        On Error GoTo Oops
        Application.EnableEvents = False
        With Me.Range("A155")
            .Value = Trim(Me.Range("'DO NOT DELETE'!A24").Text & " " & _
                          Me.Range("'DO NOT DELETE'!B24").Text & " " & _
                          Me.Range("'DO NOT DELETE'!C24").Text)
            .Characters(Start:=Len(Me.Range("'DO NOT DELETE'!A24").Text) + 2, _
                        Length:=Len(Me.Range("'DO NOT DELETE'!B24").Text)).Font.Bold = True
        End With
Oops:
        Application.EnableEvents = True
    End If
End Sub

But this isn't working. Can you not just add 'worksheetTitle'!## as you normally would like on other excel functions?

Please take a few minutes to read the forum rules, and then edit your post to add CODE tags.

Thanks.

The code has to go in the sheet module for worksheet DO NOT DELETE (the sheet where the change occurs). Change "Sheet1" as appropriate.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("A24,B24,C24")) Is Nothing Then
        On Error GoTo Oops
        Application.EnableEvents = False
        With Worksheets("Sheet1").Range("A155")
            .Value = Trim(Me.Range("A24").Text & " " & _
                          Me.Range("B24").Text & " " & _
                          Me.Range("C24").Text)
            .Characters(Start:=Len(Me.Range("A24").Text) + 2, _
                        Length:=Len(Me.Range("B24").Text)).Font.Bold = True
        End With
Oops:
        Application.EnableEvents = True
    End If
End Sub

You're welcome, good luck.