Macro code error: code is near complete

Hi, I have written a macro code as below, however, there seems to be an error.

I am trying to select all rows in sheet 1 with an X in column E to have their respective columns F, G, H & I to be copied and pasted into sheet 2 starting with cell A1, but sheet 2 should not contain any blank rows.

Can anyone pls help to fine tune the macro?

Many thanks.

Sub Copy_Rows()
  
'Copy rows containing X

Sheets("Sheet1").Select
For Each r In Sheets("Sheet1").UsedRange.Rows
    n = r.Row
        If Sheets("Sheet1").Cells(n, 5) = "X" Then
        Sheets("Sheet1").Range(Cells(n, 6), Cells(n, 9)).Copy
        Sheets("Sheet2").Select
        Range("A1").Select
        Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:=xlNone, SkipBlanks _
            :=False, Transpose:=False
            Else
    End If
    Next r

End Sub

Forum rules require VBA code to be wrapped in code tags.

Please edit your post to add the tags.

[code]
your code here
[/code]

Why not apply an auto filter to the column and copy all of the visible rows in one go?

Basic code - using autofilter, which is more efficient than looping.

Try it on a back up copy first.

Option Explicit

Sub Copy_X_Cells()

    Dim lastrow As Long: lastrow = Cells(Rows.Count, "E").End(xlUp).Row
    
    Application.ScreenUpdating = False
    
    With Sheet1
        .AutoFilterMode = False
        .Range("E1:E" & lastrow).AutoFilter field:=1, Criteria1:="x"
        .Range("F1:I" & lastrow).SpecialCells(xlCellTypeVisible).Copy Sheet2.Range("A1")
        .AutoFilterMode = False
    End With
    
    Application.CutCopyMode = False
    Application.ScreenUpdating = True

End Sub

Sheet references are to sheet code names. Adjust them as required.