Edit format of Sheet attached in Outlook

Hello:

is there a way to edit the format of the DEST sheet in the code below? I am trying to add pictures, borders, change colors or text etc but I am not sure how to do it since the DEST sheet is never visible and is automatically attached to outlook. Any help would be greatly appreciated as I have been unable to solve this for a few hours. THanks :

Sub Mail_Rangee()

    Dim Source As Range
    Dim Dest As Workbook
    Dim wb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim OutApp As Object
    Dim OutMail As Object

    Set Source = Nothing
    On Error Resume Next
    Set Source = Range("B:B, C:C,D:D, G:G,H:H, I:I, K:K,R:R, V:V,X:X, AD:AD").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If Source Is Nothing Then
        MsgBox "The source is not a range or the sheet is protected, please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set wb = ActiveWorkbook
    Set Dest = Workbooks.Add(xlWBATWorksheet)

    Source.Copy
    With Dest.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial Paste:=xlPasteValues
        .Cells(1).PasteSpecial Paste:=xlPasteFormats
        .Cells(1).Select
        Application.CutCopyMode = False
    
    End With


    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Selection of " & wb.name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    If Val(Application.Version) < 12 Then
        
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        
        FileExtStr = ".xlsx": FileFormatNum = 51
    End If

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Dest
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .to = ""
            .CC = ""
            .BCC = ""
            .Subject = "Production Report"
            .Body = "Your Production Report is attached with this email"
            .Attachments.Add Dest.FullName
            .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Hi rlsublime

Were I you, I'd place a breakpoint in your code

With Dest.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial Paste:=xlPasteValues
        .Cells(1).PasteSpecial Paste:=xlPasteFormats
        .Cells(1).Select
        Application.CutCopyMode = False
    
    End With ' Place breakpoint here

Then end the sub (reset). Now, work with the open DEST sheet...record macros that do as you wish...get them working as you wish...then copy the code to Note Pad. Now, transfer your recorded code into these lines

With Dest.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial Paste:=xlPasteValues
        .Cells(1).PasteSpecial Paste:=xlPasteFormats

        ' add new code lines here
        ' and here
        ' and here
        ' etc       

        .Cells(1).Select
        Application.CutCopyMode = False
    
    End With

Hi rlsublime

It'll probably something along these lines of code

wb.Sheets("Transfer").Shapes("Picture 2").Copy
    Dest.Sheets(1).Paste Range("A1")

Where "Transfer" is your sheet name, "Picture 2" is your picture and "A1" is the range you wish to copy to.

Hi rlsublime
Glad to be of help...if that resolves your issue please mark your Thread as solved.