Create a List of All Shapes

Hi all,

How can I make a list of all the shapes I have created in my workbook. There are a couple that I made, stopped using, but never deleted and I don't want them within the workbook anymore.

Regards:

Sub x()
    Dim wks As Worksheet
    Dim shp As Shape
    
    For Each wks In Worksheets
        For Each shp In wks.Shapes
            Debug.Print shp.Name
        Next shp
    Next wks
End Sub

If the goal is to delete them, a slight expansion on SHG's macro can offer you that opportunity:

Sub x()
Dim wks As Worksheet
Dim shp As Shape
    
    For Each wks In Worksheets
        For Each shp In wks.Shapes
            If MsgBox("Sheet " & wks.Name & " has a shape called '" & shp.Name _
                & "', delete it?", vbYesNo, "Shape Found") = vbYes Then shp.Delete
        Next shp
    Next wks

End Sub

A slight change to JB's code will let you see what you may be deleting:

Sub x()
    Dim wks         As Worksheet
    Dim shp         As Shape

    For Each wks In Worksheets
        wks.Select

        For Each shp In wks.Shapes
            shp.Select

            If MsgBox(Title:="Whee!", _
                      Prompt:="Delete """ & shp.Name & """?", _
                      Buttons:=vbYesNo) = vbYes Then
                shp.Delete
                DoEvents
            End If
        Next shp
    Next wks
End Sub

Thanks for the help guys, shg's amendment of Jerry's procedure is a keeper!

for a vba approach you can use the selection pane.
Home > Editing > Find & Select > Selection Pane.

You can use CTRL+Click to multi select and then delete.