Change Cell Value if multiple column value same

[BEEJAY]

Sorry about the poor title statement.
Looking for the following. (see attachment)

Check cells A, B and C, in row 2
If Cells A, B and C in row 3 are the same, change value in E3 to 0 (zero)
If Cells A, B, and C, in Row 4 are also same, Change value in E4 to zero

Do until no more matches.
Then, using row that doesn't match as a 'base' (row 6 in sample) repeat process...
Check A, B and C in Row 7 - If same as in row 6, change E7 to zero
Check A, B and C in Row 8 - If same as in row 6, Change E8 to zero
Do until no more matches,

Repeat above process until end in column A

Note Columns and rows shown are for sample purposes only. Actual data-base has mega columns and rows.

I hope I have made this clear enough.

Thank-you

[tigeravatar]

BEEJAY,

Give the following a try:

Sub tgr()
    
    Const Col1 As String = "A"
    Const Col2 As String = "B"
    Const Col3 As String = "C"
    Const ColUpdate As String = "E"
    
    Dim arrUpdate As Variant: arrUpdate = Intersect(ActiveSheet.UsedRange, Columns(ColUpdate)).Value
    Dim rIndex As Long
    
    With ActiveSheet.UsedRange
        For rIndex = .Row + 1 To .Row + .Rows.Count - 1
            If Cells(rIndex, Col1).Value = Cells(rIndex - 1, Col1).Value _
            And Cells(rIndex, Col2).Value = Cells(rIndex - 1, Col2).Value _
            And Cells(rIndex, Col3).Value = Cells(rIndex - 1, Col3).Value Then
                arrUpdate(rIndex + 1 - .Row, 1) = 0
            End If
        Next rIndex
    End With
    
    Intersect(ActiveSheet.UsedRange, Columns(ColUpdate)).Value = arrUpdate
    
End Sub

Hope that helps,
~tigeravatar

[BEEJAY]

tigeravatar:

Fast, effective and efficient!! Thanks so much.
This makes me look in a complete different direction than I was trying.
Have so many uses for this ( or variations of this ).

Thanks again........