Consolidate data into single table

Hi ...I've attached a workbook that should help explain this a little better.

I have a spreadsheet with data copied from another application. When I get the data, I have multiple instances of the same column, with different data. I want to consolidate them into a single list. So for example, the data when I get it has headers:
Date Ticker Volume Date Ticker Volume (etc)

I want all of my dates listed vertically, with the associated data in the next columns. Sometimes there will be additional columns though, but never more than 5.
For example, the second time I run this my columns could be
Date Ticker Trader Date Ticker Trader
or
Date Ticker Trader Estimated Price Date Ticker Trader Estimated Price

Hopefully my attachment will make it more clear!

Thanks for any assistance....

Move the data so the data starts in A1, titles that is. Then this should work for any size data groups you want to run it on.

Option Explicit

Sub ReorderColumns()
Dim Cols As Long, Grp As Long
Dim LR As Long, LC As Long

LC = Cells(1, Columns.Count).End(xlToLeft).Column
Cols = Rows(1).Find("Date", After:=[A1], _
    LookIn:=xlValues, LookAt:=xlPart).Column - 1
LR = Cells.Find("*", Cells(Rows.Count, Columns.Count), _
    SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

    For Grp = Cols + 1 To LC Step Cols
        Cells(2, Grp).Resize(LR, Cols).Copy _
            Range("A" & Rows.Count).End(xlUp).Offset(1)
    Next Grp

LR = Cells.Find("*", Cells(Rows.Count, Columns.Count), _
    SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

Range("A1", Cells(LR, Cols)).Sort Key1:=Range("A2"), Order1:=xlAscending, Header:=xlYes
Columns(Cols + 1).Resize(, 100).Clear

End Sub