Command button macro

I'm having trouble making this macro I wrote run with a command button.
The macro is a demo macro I'm writing for a much larger project, and this is basically what it does:
It allows the user to browse for a pre-formatted file. It then reads the file, stores a few values and plugs it into the designated cells in the workbook the macro is running out of.

The macro itself works when I manually run the macro. However, when I run the macro through the command button, it will execute the first half but not the last half. More specifically, it searches for the file, opens it and makes it the active window, but does not plug in the values in the designated cells.

Sub CommandButton1_Click()

    Dim varBook As Variant
    Dim otherWb As Workbook
    
    varBook = Application.GetOpenFilename
    If varBook <> False Then
        Workbooks.OpenText Filename:=varBook
        Set otherWb = ActiveWorkbook
    
        'reads & stores cell value
        Set r1Cell = Cells(1, 1)
        Set r2Cell = Cells(1, 2)
        Set r3Cell = Cells(1, 3)
       
        Set inputVariable = Cells(2, 2)
                
        'inserts values into designated cell
        ThisWorkbook.Worksheets(2).Cells(1, 1).Value = r1Cell.Value
        ThisWorkbook.Worksheets(2).Cells(1, 2).Value = r2Cell.Value
        ThisWorkbook.Worksheets(2).Cells(1, 3).Value = r3Cell.Value
        
        ThisWorkbook.Worksheets(2).Cells(6, 2).Value = inputVariable.Value
    End If
End Sub

Am I not using the correct format for the command button? or is it something else?

Thanks,

Your macro can be shortened to:

Sub CommandButton1_Click()

    Dim varBook As Variant
    Dim otherWb As Workbook
    
    varBook = Application.GetOpenFilename
    If varBook <> False Then
        Workbooks.OpenText Filename:=varBook
        Set otherWb = ActiveWorkbook
                
        'inserts values into designated cell
        ThisWorkbook.Worksheets(2).Cells(1, 1).Value = otherWb.ActiveSheet.Cells(1, 1).Value
        ThisWorkbook.Worksheets(2).Cells(1, 2).Value = otherWb.ActiveSheet.Cells(1, 2).Value
        ThisWorkbook.Worksheets(2).Cells(1, 3).Value = otherWb.ActiveSheet.Cells(1, 3).Value
        
        ThisWorkbook.Worksheets(2).Cells(6, 2).Value = otherWb.ActiveSheet.Cells(2, 2).Value
    End If
End Sub

No need to store the locations of the values in the other workbook that you are looking for. A couple things I'd ask you:

Are there multiple worksheets in the workbook that is selected? Your code does not deal with sheets, so the active sheet will be where data is taken from.

I hate to ask, but are you sure you are looking for the data in cells A1, B1, C1, and B2?

If you are satisfied with the solution(s) provided, please mark your thread as Solved.

How to mark a thread Solved
Go to the first post
Click edit
Click Go Advanced
Just below the word Title you will see a dropdown with the word No prefix.
Change to Solved
Click Save

Here's an alternative

Option Explicit

Sub CommandButton1_Click()

    Dim varBook As Variant
    Dim otherWb As Workbook
    Dim iX As Integer
    
    varBook = Application.GetOpenFilename
    If varBook <> False Then
        Workbooks.OpenText Filename:=varBook
        Set otherWb = ActiveWorkbook
        With ThisWorkbook.Worksheets(2)
            'inserts values into designated cell
            For iX = 1 To 3
                .Cells(1, iX).Value = otherWb.ActiveSheet.Cells(1, iX).Value
            Next iX
            .Cells(6, 2).Value = otherWb.ActiveSheet.Cells(2, 2).Value
        End With
    End If
End Sub