Data entered on wrksheet to be copied to new line on next wrksheet - related to date?

Hello all,

I took up the challenge to find a solution to what I am trying to achieve, but was only able to figure out how to create a new line from data entered in a single cell. Lame...I know.

What am trying to achieve is relatively straight forward, but my limited experience in vba means I require assistance.

My file has 3 worksheets; 'Operator Daily', 'Data Tracking' & 'Graphs'.
Data is manually entered only on the first worksheet 'Operator Daily', into the blue cells. The date on which data is entered is also entered in cell F2.

What I am really hoping to do, is for each date entered, the correspending data against that date is copied onto a new line in the worksheet 'Data Tracking', in the relevant cells .
There are 4 plant components with 4 data entry cells each, meaning that with each date entered, 16 cells need to be copied to 'Data Tracking'. The last worksheet 'Graphs' is already setup to collect plot points from the 'Data Tracking' worksheet.

I'm not sure what logical sequence is needed to achieve this - I have researched as many related posts as possible but are unable to find something relevant to my file.
I am really getting stuck with the fact that; The data which needs to be copied onto a new line of the 'Data Tracking' worksheet, needs to correlate to the date entered on the 'Operator Daily' worksheet.

I have attatched where the file is at, with simple cell references so you can get an idea of where I'd like data to be copied to. There is no code.

Any assistance would be greatly appreciated. Thanks in advance.

Walt

Hi Walt

Welcome to the Forum!

This code is in the attached.

Option Explicit
Sub UpDate()
    Dim LR As Long
    Dim wsS As Worksheet
    Dim wsT As Worksheet
    Set wsS = Sheets("Operator Daily")
    Set wsT = Sheets("Data Tracking")
    LR = wsT.Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Row
    With wsT
        .Range("A" & LR).Value = wsS.Range("F2").Value
        .Range("B" & LR).Value = wsS.Range("C22").Value
        .Range("C" & LR).Resize(1, 3).Value = Application.WorksheetFunction.Transpose(wsS.Range("C28:C30").Value)
        .Range("G" & LR).Value = wsS.Range("E22").Value
        .Range("H" & LR).Resize(1, 3).Value = Application.WorksheetFunction.Transpose(wsS.Range("E28:E30").Value)
        .Range("L" & LR).Value = wsS.Range("G22").Value
        .Range("M" & LR).Resize(1, 3).Value = Application.WorksheetFunction.Transpose(wsS.Range("G28:G30").Value)
        .Range("Q" & LR).Value = wsS.Range("I22").Value
        .Range("R" & LR).Resize(1, 3).Value = Application.WorksheetFunction.Transpose(wsS.Range("I28:I30").Value)
    End With
    With wsS
        .Range("F2,C22,E22,G22,I22,C28:C30,E28:E30,G28:G30,I28:I30").ClearContents
    End With
End Sub

Enter your data in Sheet "Operator Daily" and Click the UpDate Button. Be aware, Sheet "Operator Daily" DOES get cleared. Sheet2 is included only for testing.

Let me know of issues.

Hi snoproyoder

You can try to adapt the code provided in the attachment but one of our Forum Rules reads as follows:

2. Don't post a question in the thread of another member -- start your own. If you feel it's particularly relevant, provide a link to the other thread.

I looked at your file and didn't follow what you're trying to do...start your own Thread and explain further what you're after.