putting values from excel into word

Hello,

I am sure, that tjhis question has been discussed several times, but I couldn't find the answer.
I want to put values into a word documents from excel. I guess, I have to create a dot, and I have to add bookmarks, where I want to add the data.
What I don't know, how to be coded, that I want to put the value of A1 to the bookmark "Name"?

Thank you

Create Named ranges in Excel that match the Bookmarks in Word, then try this code

Option Explicit
 
Sub namesToBookmarks()
    Dim objWord As Object
    Dim docWord As Object
    Dim wb As Excel.Workbook
    Dim xlName As Excel.Name
    Dim Path As String
     
    Set wb = ActiveWorkbook
    Path = wb.Path & "\MyForm.dot" 'change the name
     
    On Error GoTo ErrorHandler
     
     'Create a new Word Session
    Set objWord = CreateObject("Word.Application")
     
    On Error GoTo ErrorHandler
     
     'Open document in word
    Set docWord = objWord.Documents.Add(Path)
     
     'Loop through names in the activeworkbook
    For Each xlName In wb.Names
         'if xlName's name is existing in document then put the value in place of the bookmark
        If docWord.Bookmarks.Exists(xlName.Name) Then
            docWord.Bookmarks(xlName.Name).Range.Text = Range(xlName.Value)
        End If
    Next xlName
     
     'Activate word and display document
    With objWord
        .Visible = True
        .ActiveWindow.WindowState = 0
        .Activate
    End With
     
     'Release the Word object to save memory and exit macro
ErrorExit:
    Set objWord = Nothing
    Exit Sub
     
     'Error Handling routine
ErrorHandler:
    If Err Then
        MsgBox "Error No: " & Err.Number & "; There is a problem"
        If Not objWord Is Nothing Then
            objWord.Quit False
        End If
        Resume ErrorExit
    End If
End Sub

Do not use bookmarks in Word but docvariables instead.
Put a string into cel A1 of sheets(1)

sub snb()
  with createobject("Word.document")
    .variables("name")= iif(sheets(1).cells(1)=""," ",sheets(1).cells(1))
    .Fields.Add .Paragraphs.Last.Range, 64, "name", False
    .fields.update
    .saveas "E:\example.doc"
    .close 0
  end with
End sub

Open the worddocument 'E:\example.doc'.

You can consider bookmarks to be a simplified solution in Word's userinterface. Users that are familiar with VBA can benefit the advantages of docvariables.

It inserts a docvariable-field into the document, so you can see the value of the documentvariable.