Macro for Conditional Transpose

Hello kundandebnath,

Welcome to the Forum!

I have added the macro below to a button on "Sheet1". This will transpose the data as you requested using the date.

'Written: June 21, 2011
'Author:  Leith Ross
'Thread:  http://www.excelforum.com/excel-programming/781072-macro-for-conditional-transpose.html
'Poster:  kundandebnath

Sub ConditionalTranspose()

  Dim Cell As Range
  Dim DstData As Range
  Dim DstRng As Range
  Dim I As Long, R As Long
  Dim Rng As Range
  Dim RngEnd As Range
  Dim Wks As Worksheet
  
    Set Wks = Worksheets("Sheet1")
    Set Rng = Wks.Range("A3")
    Set DstRng = Wks.Range("C3")
      
      Set RngEnd = Wks.Cells(Rows.Count, Rng.Column).End(xlUp)
      If RngEnd.Row < Rng.Row Then Exit Sub
      Set Rng = Wks.Range(Rng, RngEnd)
    
      Application.ScreenUpdating = False
      
        For Each Cell In Rng
          If IsDate(Cell) Then
            I = 1
              Do While Not IsDate(Cell.Offset(I, 0)) And Cell.Offset(I, 0) <> ""
                I = I + 1
              Loop
            Cell.Resize(I, 1).Copy
            DstRng.Offset(R, 0).PasteSpecial Paste:=xlPasteAll, Transpose:=True
            R = R + 1
          End If
        Next Cell
    
     Application.CutCopyMode = False
     Application.ScreenUpdating = True
     
End Sub