Find and highlight similar cells in a column

is there a way to find similar cells within a column
So i have a list of names some of them has middle name some of don't
So the common denominator between two cell will be to match a least two words out the cell in order to be a match and it must be in the same column
I don't know if this is possible to do
Thank you for any help

like this
Martinez L Pedro
Martinez Pedro
Pedro Martinez lopez
Pedro Martinez l
Pedro Martinez

Hello Pedro,

Do you have an actual name list that you can post?

Hello Pedro,

Thank you for posting the workbook. What do you want to do once a possible match has been found?

Hello Pedro,

Can you give me an example of what a grouping would like?

Hello Pedro,

That answers my question perfectly. Thank you. Now to start coding.

Hello Pedro,

This macro will place the groups on the active worksheet starting in cell "E2". There is button on the sheet to run the macro. Each group is separated by a blank line.

Option Explicit

Sub GroupNames()

  Dim Cell As Range
  Dim Dict As Object
  Dim I As Long
  Dim Key As Variant
  Dim NameList As Variant
  Dim R As Long
  Dim RegExp As Object
  Dim Rng As Range
  Dim RngEnd As Range
  Dim Text As String
  Dim Wks As Worksheet
  
    Set Wks = ActiveSheet
    
    Set Rng = Wks.Range("A2")
    Set RngEnd = Wks.Cells(Rows.Count, Rng.Column).End(xlUp)
    If RngEnd.Row < Rng.Row Then Exit Sub Else Set Rng = Wks.Range(Rng, RngEnd)
    
    Set Dict = CreateObject("Scripting.Dictionary")
    Dict.CompareMode = vbTextCompare
    
    Set RegExp = CreateObject("VBScript.RegExp")
    RegExp.IgnoreCase = True
    RegExp.Pattern = "(\w+)(?:\s|\,\s)(\w+)(\s*.*)"
    
    
      For Each Cell In Rng
        Text = Trim(Cell.Value)
        If Text <> "" Then
           I = InStr(1, Text, ",")
           If I > 0 Then
              Key = RegExp.Replace(Text, "$2 $1")
           Else
              Key = RegExp.Replace(Text, "$1 $2")
           End If
           
           If Not Dict.Exists(Key) Then
              Dict.Add Key, Text
           Else
              Dict(Key) = Dict(Key) & "|" & Text
           End If
        End If
      Next Cell
      
    For Each Key In Dict.Keys
      NameList = Split(Dict(Key), "|")
      Wks.Range("E2").Offset(R, 0).Resize(UBound(NameList) + 1, 1) = WorksheetFunction.Transpose(NameList)
      R = R + UBound(NameList) + 2
    Next Key
    
End Sub