Vertical to Horizontal Data Special Conditions

I am using some data scraping software to get all the image urls from the site so I can use them in my other database. Here is the problem the data is coming in vertically and I need it horizontally "well use transpose" yes works but there are about 53,000 images and do not want to go through it one line at a time. I would like to use a macro for this. Here is what I have and what I need the finished product to look like.


SKU 1
Image1
Image2
Image3
Image4
Image5
SKU 2
Image1
Image2
Image3
Image4
Image5
Image6
Image7
SKU 3
Image1
Image2


Needs to be like this:

SKU 1 | Image1 | Image2 | Image3 | Image4| Image5
SKU 2 | Image1 | Image2 | Image3 | Image4 | Image5 | Image6 | Image7
SKU 3 | Image1 | Image2


The number of images change any where from 1 - 19 images per sku.

I hope I explained this well enough!
Any help would be much appreciated.

Thanks,
Guy

This should do it:

Option Explicit

Sub ReformatSKUs()
Dim FR As Long, LR As Long, NR As Long, Rw As Long

Application.ScreenUpdating = False
LR = Range("A" & Rows.Count).End(xlUp).Row
NR = 1
FR = 1

For Rw = 1 To LR
    If Rw <> LR Then
        If Left(Range("A" & Rw + 1), 3) = "SKU" Then
            Range("A" & FR, "A" & Rw).Copy
            Range("C" & NR).PasteSpecial xlPasteAll, Transpose:=True
            NR = NR + 1
            FR = Rw + 1
        End If
    Else
        Range("A" & FR, "A" & Rw).Copy
        Range("C" & NR).PasteSpecial xlPasteAll, Transpose:=True
    End If
Next Rw

Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

The macro worked but it in not formatted the right way.

The macro you gave me:
SKU | image | image | image | SKU | image etc...

needs to be:

SKU | image | image | image | image
SKU | image | image
SKU | image | image | image | image | image | image
SKU | image | image | image


Thank You

First, please do not QUOTE my entire post, now the code that won't work is doubled in this thread. EDIT that post above and remove that, if you would...

Hehe.. Your post #1 indicated SKU was at the start of each string, but that wasn't true. Always start with a sample workbook, eliminates mistakes like that. Here's the redone code:

Option Explicit

Sub ReformatSKUs()
Dim FR As Long, LR As Long, NR As Long, Rw As Long

Application.ScreenUpdating = False
LR = Range("A" & Rows.Count).End(xlUp).Row
NR = 1
FR = 2

For Rw = 2 To LR
    If Rw <> LR Then
        If Left(Range("A" & Rw + 1), 4) <> "http" Then
            Range("A" & FR, "A" & Rw).Copy
            Range("C" & NR).PasteSpecial xlPasteAll, Transpose:=True
            NR = NR + 1
            FR = Rw + 1
        End If
    Else
        Range("A" & FR, "A" & Rw).Copy
        Range("C" & NR).PasteSpecial xlPasteAll, Transpose:=True
    End If
Next Rw

Cells.Columns.AutoFit
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub