Can you exclude coloums from a macro that runs automatically?

**snoopy1461** · 03-31-2011, 08:16 AM

I have a code that when the user clicks off the cell it automatically sets it to 'PROPER'.

Can i set it to exclude coloums suchs as D & N?

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim rngSrc As Range
   On Error GoTo err_handler
   Application.EnableEvents = False
   For Each rngSrc In Target.Cells
      With rngSrc
         If Not .HasFormula Then .Value = StrConv(.Value, vbProperCase)
      End With
   Next rngSrc

clean_up:
   Application.EnableEvents = True
   Exit Sub

err_handler:
   MsgBox Err.Description
   Resume clean_up
End Sub

**watersev** · 03-31-2011, 09:14 AM

hi, snoopy1461, try this out:

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim rngSrc As Range
   On Error GoTo err_handler
   Application.EnableEvents = False
   For Each rngSrc In Target.Cells
      With rngSrc
         If rngSrc.Column <> 4 And rngSrc.Column <> 14 Then
            If Not .HasFormula Then .Value = StrConv(.Value, vbProperCase)
         End If
      End With
   Next rngSrc

clean_up:
   Application.EnableEvents = True
   Exit Sub

err_handler:
   MsgBox Err.Description
   Resume clean_up
End Sub