Code to shrink font size after the first 3 characters and spaces

[trickyricky]

I'm looking for a way to quickly make the font size of a text string within a cell smaller than the first 3 characters. For Example:

11 Smaller
12 Smaller
13 Smaller
14 Smaller
etc...

The numbers I want the font size to be 11 for example and for the "Smaller" part I want the font size to be 9.

I need to be able to do this for multiple cells quickly instead of manually going to each cell and highlighting the smaller part and changing the font size.

Thanks in advance!

[protonLeah]

Does this one work?

Sub test()
    Dim SpaceLocation  As Long, _
        TextLength  As Long
    
    With ActiveCell
        TextLength = Len(.Text)
        SpaceLocation = InStr(1, .Text, " ")
        .Characters(Start:=1, Length:=SpaceLocation - 1).Font.Size = 11
        .Characters(Start:=SpaceLocation + 1, Length:=TextLength - SpaceLocation - 1).Font.Size = 9
    End With
End Sub

[trickyricky]

Close. It's setting the first three characters to font size 11 which is right, but it's not setting the last letter on the very end to size 9 like it should. Also would be slick if it could work on a range of cells instead of just the active cell.

P.S.

Some of the cells i'm wanting to do this for actually look more like this:

11 NO GRP
12 NO FP
13 ENDORUSH
14 SPD GRP
15 SPD FP
etc..

In other words some text in the cells after the numbers have spaces in them and should all be size 9.

[trickyricky]

Okay here's what I do, I go ahead and set the font for everything to size 9 then I Run this code:

Sub Font_Sizer()
    Dim SpaceLocation  As Long, _
        TextLength  As Long
    
    With ActiveCell
        TextLength = Len(.Text)
        SpaceLocation = InStr(1, .Text, " ")
        .Characters(Start:=1, Length:=SpaceLocation - 1).Font.Size = 11
    End With
End Sub

But I want this to work on a selection of cells. I tried changing the active cell part to selection but it didn't work like I hoped. Please help if you can!

[Andy Pope]

Sub X()

    Dim rngCell As Range
    Dim lngPos As Long
    
    If Not TypeOf Selection Is Range Then Exit Sub
    
    For Each rngCell In Selection.Cells
        lngPos = InStr(rngCell.Value, " ")
        If lngPos > 0 Then
            rngCell.Font.Size = 11
            rngCell.Characters(lngPos + 1, Len(rngCell.Value)).Font.Size = 9
        End If
    Next
    
    
End Sub

[trickyricky]

Booyah! Thank you kindly! You will get the scales!