how to close a file opened with "Workbooks.Open Filename:=sWb"

I am looking to (1) close this file and (2) simplify\clean up the overall macro. Any recommendations.



****************************************************

Option Explicit
Sub UpdatePivotTables()
'
' UpdatePivotTables Macro
' Macro recorded 2/28/2011 by Gary Gremel
' Keyboard Shortcut: Ctrl+Shift+U

' Prompts User to select file and import into Automated Report
    
    Application.ScreenUpdating = False
    Dim sFil   As String
    Dim sTitle As String
    Dim sWb    As String
    Dim iFilterIndex As Integer
On Error GoTo err_handler
    ' Set up list of file filters
    sFil = "Excel Files (*.xls),*.xls"
    ' Display *.xls by default
    iFilterIndex = 1
    ' Set the dialog box caption
    sTitle = "Select this week's BRT Weekly Resource Report."
    ' Get the filename
    sWb = Application.GetOpenFilename(sFil, iFilterIndex, sTitle)
    Workbooks.Open Filename:=sWb
    
' Copies BRT Report from selected file to Weekly Resource Report.
    Sheets("BRT Report").Select
    Range("A4:BB3000").Select
    Selection.Copy
    Windows("Weekly Resource Report.xls").Activate
    Sheets("BRT Report").Select
    Range("A4").Select
    ActiveSheet.Paste
 
' Copies No of Wkdays Calc from selected file to Weekly Resource Report.
    Workbooks.Open Filename:=sWb
    Sheets("No of Wkdays Calc").Select
    Range("A1:BB3000").Select
    Selection.Copy
    Windows("Weekly Resource Report.xls").Activate
    Sheets("No of Wkdays Calc").Select
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

' Updates the Pivot table Cache and data being reported in the Weekly Resource Report.
    Sheets("Pivot by Division Detail").Select
    ActiveSheet.PivotTables("PivotTable1").PivotCache.Refresh
    Sheets("Pivot by Division").Select
    Range("C13").Select
    ActiveSheet.PivotTables("PivotTable1").PivotCache.Refresh
    Sheets("Pivot by Region").Select
    Range("D8").Select
    ActiveSheet.PivotTables("PivotTable1").PivotCache.Refresh

' Return to instruction tab
    Sheets("Instructions").Select
    Range("A1").Select
    Exit Sub
err_handler:
MsgBox "No selection made"



End Sub

I don't know if the changes in the Pivot table stuff later will work since I rarely work with Pivot Tables and you didn't include workbooks to test this one, but the stuff at the beginning I know works and was your original question, anyway. This will give you syntax to play with:

Option Explicit

Sub UpdatePivotTables()
'
' UpdatePivotTables Macro
' Macro recorded 2/28/2011 by Gary Gremel
' Keyboard Shortcut: Ctrl+Shift+U

' Prompts User to select file and import into Automated Report
    
Application.ScreenUpdating = False
Dim sFil   As String
Dim sTitle As String
Dim sWb    As String
Dim iFilterIndex As Long
Dim wb As Workbook
Dim wsRpt As Worksheet
Dim wsNum As Worksheet
On Error GoTo err_handler
'Setup
    sFil = "Excel Files (*.xls),*.xls"                              'list of file filters
    iFilterIndex = 1                                                'Display *.xls by default
    sTitle = "Select this week's BRT Weekly Resource Report."       'caption
    sWb = Application.GetOpenFilename(sFil, iFilterIndex, sTitle)   'filename
    If sWb = "False" Then Exit Sub
    Set wsNum = ThisWorkbook.Sheets("No of Wkdays Calc") 'Num of days target sheet
    Set wsRpt = ThisWorkbook.Sheets("BRT Report")        'Weekly Resource Report sheet
    
'Open file and copy data
    Set wb = Workbooks.Open(sWb)
    wb.Sheets("BRT Report").Range("A4:BB3000").Copy wsRpt.Range("A4")
    wb.Sheets("No of Wkdays Calc").Range("A1:BB3000").Copy
    wsNum.Range("A1").PasteSpecial xlPasteValues
    wb.Close False

' Updates the Pivot table Cache and data being reported in the Weekly Resource Report.
    With ThisWorkbook.Sheets("Pivot by Division Detail")
        .PivotTables("PivotTable1").PivotCache.Refresh
        .Range("C13").Select
        .PivotTables("PivotTable1").PivotCache.Refresh
    End With
    ThisWorkbook.Sheets("Pivot by Region").PivotTables("PivotTable1").PivotCache.Refresh

' Return to instruction tab
    ThisWorkbook.Sheets("Instructions").Activate
    Range("A1").Select
    Application.ScreenUpdating = True
    Exit Sub

err_handler:
    Application.ScreenUpdating = True
    MsgBox "No selection made"
End Sub