dependent combo boxes

hi,
Need help on the following,

My work book has 4 cols (Name, Vendor, Product, Sub Product)

User Form 1 has 4 combo boxes with same above col names.

I need a code that does the foll;

- When Combo Box ‘Name’ is selected - should list the following ‘Unique’ Values from Col 'Name'
‘Sales Man 1’ & ‘Sales Man 2’

- if ‘Sales Man 1’ is selected in Combo Box ‘Name’,
Combo Box ‘Vendor’ - should list the following ‘Unique’ Values from col 'vendor'
‘Vendor 1’ & ‘Vendor 2’

- if ‘Vendor 1’ is selected in Combo Box ‘Vendor’,
Combo Box ‘Product’ - should list the following ‘Unique’ Values from col 'Product'
‘Product 1’ & ‘Product 2’

- if ‘Product 1is selected in Combo Box ‘Product’,
Combo Box ‘Sub Product’ - should list the following ‘Unique’ Values from col 'Sub Product
‘SP 1.1’ , ‘SP 1.2’, ‘SP 1.3’

Thanks
R

Try this

It runs off Workbook_Open at present, though that's easily changed to what-ever you wish.
borrowed code from here: http://www.excelforum.com/excel-prog...-combobox.html

Private Sub Workbook_Open()
UserForm1.agent.Clear
Sheet1.Range("A1").AutoFilter
Call FillCombobox(Sheet1.Range("A2", Sheet1.Cells(Rows.Count, "A").End(xlUp)), UserForm1.agent)
UserForm1.Show
End Sub
------

Private Sub agent_Change()
UserForm1.vendor.Clear
If Sheet1.FilterMode = True Then: Sheet1.ShowAllData
Sheet1.Range("A1").AutoFilter field:=1, Criteria1:="=" & UserForm1.agent.Value
Call FillCombobox(Sheet1.Range("B2", Sheet1.Cells(Rows.Count, "B").End(xlUp)).SpecialCells(xlCellTypeVisible), UserForm1.vendor)
End Sub
-----------

Private Sub vendor_Change()
UserForm1.product.Clear
Sheet1.Range("A1").AutoFilter field:=2, Criteria1:="=" & UserForm1.vendor.Value
Sheet1.Range("A1").AutoFilter field:=3
Call FillCombobox(Sheet1.Range("C2", Sheet1.Cells(Rows.Count, "C").End(xlUp)).SpecialCells(xlCellTypeVisible), UserForm1.product)
End Sub
-----------

Private Sub product_Change()
UserForm1.subproduct.Clear
Sheet1.Range("A1").AutoFilter field:=3, Criteria1:="=" & UserForm1.product.Value
Call FillCombobox(Sheet1.Range("D2", Sheet1.Cells(Rows.Count, "D").End(xlUp)).SpecialCells(xlCellTypeVisible), UserForm1.subproduct)
End Sub
--------------

Sub FillCombobox(entRng As Range, cbox As Object)
Dim cllrng As Range
Dim toAdd As New Collection
Dim collItem

On Error Resume Next
For Each cllrng In entRng
    toAdd.Add cllrng.Value, CStr(cllrng.Value)
Next cllrng
On Error GoTo 0

For Each collItem In toAdd
    cbox.Object.AddItem collItem
Next collItem
End Sub